ピコピコプラネットのクエリ例

LTP_01 のリソースの記述を取得する.rq

# Turtle 形式で出力させるのが見やすくておすすめです
BASE <https://mltd.pikopikopla.net/resource/>
DESCRIBE <LTP_01>

Thank You! が収録されたアルバム.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX : <http://schema.org/>

SELECT ?album ?artist ?position
WHERE {
  ?s a :MusicAlbum ;
    :name ?album ;
    :track [
      :recordingOf/:name "Thank You!" ;
      :byArtist/:name ?artist ;
      :position ?position
    ] .
}

ミリオン声優のTwitterアカウント.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX mltd: <https://mltd.pikopikopla.net/mltd-schema#>
PREFIX : <http://schema.org/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

SELECT ?name ?account ?url
WHERE {
  ?s a mltd:VoiceActor ;
    :name ?name ;
    foaf:account [
      foaf:name "Twitter" ;
      foaf:accountName ?account ;
      foaf:page ?url
    ] .
}

ミリオン声優の事務所別人数.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX mltd: <https://mltd.pikopikopla.net/mltd-schema#>
PREFIX : <http://schema.org/>

SELECT ?agency (COUNT(?agency) AS ?people)
WHERE {
  ?s a mltd:VoiceActor ;
    :memberOf ?agency .
}
GROUP BY ?agency
ORDER BY DESC(?people)

ユニットのメンバーと収録されているアルバム.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX : <http://schema.org/>

SELECT DISTINCT ?album ?unit_name (GROUP_CONCAT(?member;separator=",") AS ?members)
WHERE {
  ?unit a :MusicGroup ;
    :member/:name ?member ;
    ^:byArtist/^:track/:name ?album .
  OPTIONAL { ?unit :name ?unit_name }
}
GROUP BY ?unit ?unit_name ?album

七尾百合子が参加している楽曲.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX mltd: <https://mltd.pikopikopla.net/mltd-schema#>
PREFIX : <http://schema.org/>

SELECT ?album ?position ?song
WHERE {
  ?s a :MusicAlbum ; 
    :name ?album ;
    :track [
      :recordingOf/:name ?song ;
      :byArtist/:member?/:name "七尾百合子" ;
      :position ?position
    ] .
}

収録された回数の多い楽曲.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX : <http://schema.org/>

SELECT ?song (COUNT(?song) AS ?count)
WHERE {
  ?s a :MusicAlbum ;
    :name ?album ;
    :track [
      :recordingOf/:name ?song ;
      :byArtist/:name ?artist 
    ] .
}
GROUP BY ?song
ORDER BY DESC(?count)

同じ読みの名前を持つミリオン声優.rq

BASE <https://mltd.pikopikopla.net/resource/>
PREFIX mltd: <https://mltd.pikopikopla.net/mltd-schema#>
PREFIX : <http://schema.org/>

SELECT (STR(?givenName) AS ?名前) (COUNT(?s) AS ?人数) (GROUP_CONCAT(?name) AS ?該当者)
WHERE {
  ?s a mltd:VoiceActor ;
    :name ?name ;
    :givenName ?givenName .
  FILTER(LANG(?givenName) = 'ja-hira')
}
GROUP BY ?givenName
HAVING (?人数 >= 2)