PKGBUILD hunspell-gl from git

pkgname=hunspell-gl-git
pkgver=20.08.r394.g475ae3d
pkgrel=1
epoch=2
pkgdesc="Galician hunspell dictionaries. RAG/ILG normative"
arch=(any)
url="https://gitlab.com/proxecto-trasno/hunspell-gl"
license=('GPL3')
optdepends=('hunspell:  the spell checking libraries and apps')
makedepends=('scons' 'python-pyicu' 'qt5-webengine')
provides=('hunspell-gl')
conflicts=('hunspell-gl')
source=("${pkgname}::git+https://gitlab.com/proxecto-trasno/hunspell-gl.git")
md5sums=("SKIP")

pkgver() {
  cd "$pkgname"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/$pkgname"
  scons code=gl_ES aff=norma,trasno,unidades dic=comunidade,rag,norma,trasno,unidades,uvigo,wiktionary rep=comunidade,rag,wikipedia
}

package(){
    cd "$srcdir"
    install -dm755 ${pkgdir}/usr/share/hunspell
    install -m644 ${pkgname}/build/gl_ES.dic ${pkgname}/build/gl_ES.aff $pkgdir/usr/share/hunspell

    # myspell symlinks
    install -dm755 ${pkgdir}/usr/share/myspell/dicts
    pushd $pkgdir/usr/share/myspell/dicts
    for file in $pkgdir/usr/share/hunspell/*; do
        ln -sv /usr/share/hunspell/$(basename $file) .
    done
    popd

    # docs
    install -dm644 $pkgdir/usr/share/doc/$pkgname

    # Install webengine dictionaries
    install -d "$pkgdir"/usr/share/qt/qtwebengine_dictionaries/
    for _file in "$pkgdir"/usr/share/hunspell/*.dic; do
    _filename=$(basename $_file)
      qwebengine_convert_dict $_file "$pkgdir"/usr/share/qt/qtwebengine_dictionaries/${_filename/\.dic/\.bdic}
    done
}