Simple minimal Android Gradle <-> Git tag version mapping

build.gradle

android {
    // ...
    defaultConfig {
        def gitDescribe = "git -C ${rootDir} describe --tags --long --dirty".execute().text.trim()
        def (tag, commitsString, commitSha, dirty) = gitDescribe ? gitDescribe.tokenize('-') : []
        def (tagMajor, tagMinor, tagPatch) = tag ? tag.tokenize('.') : []
        def commits = commitsString ? commitsString.toInteger() : 0
        def tmpMajor = tagMajor ? tagMajor.replaceAll('^v', '') : ''
        def major = (tmpMajor && tmpMajor.isNumber()) ? tmpMajor.toInteger() : 0
        def minor = (tagMinor && tagMinor.isNumber()) ? tagMinor.toInteger() : 0
        def patch = (tagPatch && tagPatch.isNumber()) ? tagPatch.toInteger() : 1
        def suffix = !gitDescribe || !tag || commits > 0 || (dirty == 'dirty') ? 'SNAPSHOT' : ''

        printf("\n" +
                "--------VERSION DATA--------" + "\n" +
                "- gitDescribe: " + gitDescribe + "\n" +
                "- tag: " + tag + "\n" +
                "- commits: " + commits + "\n" +
                "- commitSha: " + commitSha + "\n" +
                "- dirty: " + (dirty == 'dirty') + "\n" +
                "- suffix: " + suffix + "\n" +
                "----------------------------" + "\n" +
                "- tagMajor: " + tagMajor + "\n" +
                "- tagMinor: " + tagMinor + "\n" +
                "- tagPatch: " + tagPatch + "\n" +
                "----------------------------" + "\n" +
                "- major: " + major + "\n" +
                "- minor: " + minor + "\n" +
                "- patch: " + patch + "\n" +
                "----------------------------" + "\n" +
                "")

        versionCode major * 10000 + minor * 100 + patch
        versionName "$major.$minor.$patch" + (suffix ? "-$suffix" : '')

        printf("\n" +
                "--------FINAL DATA--------" + "\n" +
                "- versionCode: " + versionCode + "\n" +
                "- versionName: " + versionName + "\n" +
                "----------------------------" + "\n" +
                "")
        // ...
    }
    // ...
}