atomのterminal-plusでfocusをいい感じにtoggleするやつ

init.coffee

focusMain = (e) ->
  atom.workspace.getActivePane().activate()
  for panel in atom.workspace.getBottomPanels()
    if panel.item[0]?.className == 'terminal-plus terminal-view'
      panel.item.terminal?.blur()

focusTerminal = (e) ->
  terminalFound = false
  for panel in atom.workspace.getBottomPanels()
    if panel.item[0]?.className == 'terminal-plus terminal-view'
      terminalFound = true
      if panel.isVisible()
        panel.item.focusTerminal()
      else
        panel.item.toggle()

  unless terminalFound
    for panel in atom.workspace.getBottomPanels()
      if panel.item[0]?.className == 'terminal-plus status-bar'
        panel.item.toggle()

atom.commands.add 'atom-workspace',
  'editor:focus-main':  focusMain
  'editor:focus-terminal': focusTerminal
  'editor:toggle-focus-terminal': ->
    if document.activeElement.className == 'terminal'
      focusMain()
    else
      focusTerminal()

keymap.cson

'.workspace':
  'cmd-;': 'editor:toggle-focus-terminal'