The demo 100 from fast led with three buttons

demo100Button.ino

#include "FastLED.h"
FASTLED_USING_NAMESPACE

#include <EasyButton.h>


// FastLED "100-lines-of-code" demo reel, showing just a few 
// of the kinds of animation patterns you can quickly and easily 
// compose using FastLED.  
//
// This example also shows one easy way to define multiple 
// animations patterns and have them automatically rotate.
//
// -Mark Kriegsman, December 2014

#if defined(FASTLED_VERSION) && (FASTLED_VERSION < 3001000)
#warning "Requires FastLED 3.1 or later; check github for latest code."
#endif

#define DATA_PIN    D6
//#define CLK_PIN   4
#define LED_TYPE    WS2811
#define COLOR_ORDER GRB
#define NUM_LEDS    30
CRGB leds[NUM_LEDS];

#define BRIGHTNESS          96
#define FRAMES_PER_SECOND  120
uint8_t gCurrentPatternNumber = 0; // Index number of which pattern is current
uint8_t gHue = 0; // rotating "base color" used by many of the patterns
uint8_t gStyle = 0 ; // Different styles. 0 = Manual Hue, 1 = Auto Hue 
const uint8_t STYLE_MANUAL_HUE = 0 ; 
const uint8_t STYLE_AUTOMATIC_HUE = 1 ; 
const uint8_t STYLE_MAX = STYLE_AUTOMATIC_HUE ;

const int BUTTON_NEXT_PATTERN = D4;    // the number of the pushbutton pin
EasyButton nextPatternButton(BUTTON_NEXT_PATTERN);
const int BUTTON_HUE = D2;
EasyButton HueButton(BUTTON_HUE);
const int BUTTON_STYLE = D3;
EasyButton StyleButton(BUTTON_STYLE);

void setup() {
  delay(3000); // 3 second delay for recovery
  
  // tell FastLED about the LED strip configuration
  FastLED.addLeds<LED_TYPE,DATA_PIN,COLOR_ORDER>(leds, NUM_LEDS).setCorrection(TypicalLEDStrip);
  //FastLED.addLeds<LED_TYPE,DATA_PIN,CLK_PIN,COLOR_ORDER>(leds, NUM_LEDS).setCorrection(TypicalLEDStrip);

  // set master brightness control
  FastLED.setBrightness(BRIGHTNESS);
  Serial.begin(115200);
  Serial.println("\n\nStarting\n\n");

  nextPatternButton.begin();
  nextPatternButton.onPressed(nextPattern);
  
  HueButton.begin();  
  StyleButton.begin();
  StyleButton.onPressed(nextStyle);

  // gCurrentPatternNumber = 6  ;
  // gHue = 150; // 150 = Blue 

  
}


// List of patterns to cycle through.  Each is defined as a separate function below.
typedef void (*SimplePatternList[])();
SimplePatternList gPatterns = { rainbow, fill, rainbowWithGlitter, confetti, sinelon, juggle, bpm, fill, single };


  
void loop()
{
  nextPatternButton.read();
  HueButton.read();
  StyleButton.read();

  if( HueButton.isPressed() ) {
    gHue++ ; 
  }



  if( gStyle ) { 
    // Call the current pattern function once, updating the 'leds' array
    gPatterns[gCurrentPatternNumber]();
  
  } else {
      for( int i = 0; i < NUM_LEDS; i++) { //9948
      leds[i] = CRGB::Black;
    }
  }
  
  // send the 'leds' array out to the actual LED strip
  FastLED.show();  
  // insert a delay to keep the framerate modest
  FastLED.delay(1000/FRAMES_PER_SECOND); 



  // do some periodic updates
  // EVERY_N_MILLISECONDS( 20 ) { gHue++; } // slowly cycle the "base color" through the rainbow
  // EVERY_N_SECONDS( 10 ) { nextPattern(); } // change patterns periodically

}

#define ARRAY_SIZE(A) (sizeof(A) / sizeof((A)[0]))

void single() {
  for( int i = 0; i < NUM_LEDS; i++) { //9948
    leds[i] = CRGB::Black;
  }
    leds[NUM_LEDS-1] = CHSV( gHue, 255, 255);
}

void fill() {
  for( int i = 0; i < NUM_LEDS; i++) { //9948
    leds[i] = CHSV( gHue, 255, 255);
  }
}

void nextStyle() {
  gStyle = !gStyle ;
}
void nextPattern()
{
  // add one to the current pattern number, and wrap around at the end
  gCurrentPatternNumber = (gCurrentPatternNumber + 1) % ARRAY_SIZE( gPatterns);
}

void rainbow() 
{
  // FastLED's built-in rainbow generator
  fill_rainbow( leds, NUM_LEDS, gHue, 7);
}

void rainbowWithGlitter() 
{
  // built-in FastLED rainbow, plus some random sparkly glitter
  rainbow();
  addGlitter(80);
}

void addGlitter( fract8 chanceOfGlitter) 
{
  if( random8() < chanceOfGlitter) {
    leds[ random16(NUM_LEDS) ] += CRGB::White;
  }
}

void confetti() 
{
  // random colored speckles that blink in and fade smoothly
  fadeToBlackBy( leds, NUM_LEDS, 10);
  int pos = random16(NUM_LEDS);
  leds[pos] += CHSV( gHue + random8(64), 200, 255);
}

void sinelon()
{
  // a colored dot sweeping back and forth, with fading trails
  fadeToBlackBy( leds, NUM_LEDS, 10);
  // int pos = beatsin16( 13, 0, NUM_LEDS-1 );
  int pos = beatsin16( 50, 0, NUM_LEDS-1 );
  leds[pos] += CHSV( gHue, 255, 192);
}

void bpm()
{
  // colored stripes pulsing at a defined Beats-Per-Minute (BPM)
  uint8_t BeatsPerMinute = 62;
  CRGBPalette16 palette = PartyColors_p;
  uint8_t beat = beatsin8( BeatsPerMinute, 64, 255);
  for( int i = 0; i < NUM_LEDS; i++) { //9948
    leds[i] = ColorFromPalette(palette, gHue+(i*2), beat-gHue+(i*10));
  }
}

void juggle() {
  // eight colored dots, weaving in and out of sync with each other
  fadeToBlackBy( leds, NUM_LEDS, 20);
  byte dothue = 0;
  for( int i = 0; i < 8; i++) {
    leds[beatsin16( i+7, 0, NUM_LEDS-1 )] |= CHSV(dothue, 200, 255);
    dothue += 32;
  }
}