Warp Terminal - Arch Linux

README.md

This small change aims to not compete with pandoc dependencies. Hence the change of name warp to warp-terminal.

---

Esta pequena alteração visa não competir com as dependências do pandoc. Por isso a alteração do nome warp para warp-terminal.

desktop.patch

--- src/squashfs-root/usr/share/applications/dev.warp.Warp.desktop	2024-02-08 19:26:03.570808812 -0300
+++ src/squashfs-root/usr/share/applications/dev.warp.Warp.copy.desktop	2024-02-08 19:27:29.943884931 -0300
@@ -7,7 +7,7 @@
 Name=Warp
 GenericName=TerminalEmulator
 
-Exec=warp %U
+Exec=warp-terminal %U
 StartupWMClass=dev.warp.Warp
 
 Keywords=shell;prompt;command;commandline;cmd;

PKGBUILD

# Maintainer: irmluity <45vw4yz8g@mozmail.com>

pkgname=warp-terminal
pkgver=0.2024.01.30.16.52.stable_01
pkgrel=1
pkgdesc="Warp is a modern, Rust-based terminal with AI built in so you and your team can build great software, faster"
arch=(x86_64)
url='https://warp.dev'
license=('LicenseRef-warp')
depends=('hicolor-icon-theme' 'zlib' 'glibc')
options=(!strip)
source=(
    "${pkgname}-${pkgver}-$CARCH.AppImage::https://releases.warp.dev/stable/v${pkgver}/Warp-$CARCH.AppImage"
    "LICENSE::https://raw.githubusercontent.com/warpdotdev/Warp/main/LICENSE"
    "desktop.patch"
)
sha256sums=(
    "e370069d43435760aff645d658a24b8205cb36eb25ae8f3656cf36fa3c1d878b"
    "SKIP"
    "SKIP"
)

prepare() {
    cd "${srcdir}"
    chmod a+x "${pkgname}-${pkgver}-$CARCH.AppImage"
    "./${pkgname}-${pkgver}-$CARCH.AppImage" --appimage-extract >/dev/null
    patch -Np1 -i "${srcdir}/desktop.patch"
}

package() {
    install -Dm755 "${srcdir}/${pkgname}-${pkgver}-$CARCH.AppImage" "$pkgdir/opt/${pkgname}/${pkgname}.AppImage"
    cd ${srcdir}/squashfs-root/usr/share/icons
    find . -type f -exec install -Dm 644 {} "$pkgdir/usr/share/icons"/{} \;
    cd ${srcdir}/squashfs-root/usr/share/applications
    find . -type f -exec install -Dm 644 {} "$pkgdir/usr/share/applications"/{} \;
    install -dm755 "${pkgdir}/usr/bin"
    ln -s "/opt/${pkgname}/${pkgname}.AppImage" "${pkgdir}/usr/bin/warp-terminal"
    install -Dm644 "$srcdir/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}