wxwidgets-gtk without egl support

PKGBUILD

# this is a version of wxwidgets-gtk built with egl support disabled
# to help debug this issue with slade:
# https://github.com/sirjuddington/SLADE/issues/1390

# modified from the official PKGBUILD:
# https://github.com/archlinux/svntogit-packages/blob/packages/wxwidgets/trunk/PKGBUILD

pkgname=wxwidgets-gtk3-no-egl-debug
pkgver=3.2.2.1
pkgrel=1
arch=(x86_64)
url='https://wxwidgets.org'
license=(custom:wxWindows)
conflicts=(wxgtk3)
replaces=(wxgtk3)
provides=(wxgtk3 wxwidgets-common wxwidgets-gtk3 wxwidgets)
options=(debug !strip)
makedepends=(cmake gst-plugins-base glu webkit2gtk libnotify qt5-base sdl2 libmspack)
source=("wxWidgets"::"git+https://github.com/wxWidgets/wxWidgets.git#tag=v3.2.2.1")
sha256sums=('SKIP')

build() {
  cd wxWidgets
  git submodule update --init 3rdparty/*
  cd ..

  cmake -B build-gtk3 -S wxWidgets \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Debug \
    -DwxBUILD_TOOLKIT=gtk3 \
    -DwxUSE_OPENGL=ON \
    -DwxUSE_GLCANVAS_EGL=OFF \
    -DwxUSE_REGEX=sys\
    -DwxUSE_ZLIB=sys \
    -DwxUSE_EXPAT=sys \
    -DwxUSE_LIBJPEG=sys \
    -DwxUSE_LIBPNG=sys \
    -DwxUSE_LIBTIFF=sys \
    -DwxUSE_LIBLZMA=sys \
    -DwxUSE_LIBMSPACK=ON \
    -DwxUSE_PRIVATE_FONTS=ON \
    -DwxUSE_GTKPRINT=ON
  cmake --build build-gtk3

# Run configure to generate the Makefile, cmake doesn't install translations
  cd wxWidgets
  ./configure --prefix=/usr
}

package() {
  DESTDIR="$pkgdir" cmake --install build-gtk3
  install -Dm644 wxWidgets/wxwin.m4 -t "$pkgdir"/usr/share/aclocal
  make DESTDIR="$pkgdir" -C wxWidgets locale_install  
  install -Dm644 wxWidgets/docs/licence.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}