python-anyconfig-0.9.10

PKGBUILD

# Maintainer: Morten Linderud <morten@linderud.pw>  
# Maintainer: Gardar <aur@gardar.net>
pkgbase="python-anyconfig"
pkgname=("python-anyconfig" "python2-anyconfig")
pkgver=0.9.10
pkgrel=2
pkgdesc='Generic access to configuration files in any formats (to be in the future)'
url='https://github.com/ssato/python-anyconfig'
arch=('any')
license=('MIT')
makedepends=('python' 'python-setuptools'
             'python2' 'python2-setuptools')
checkdepends=('python-tox')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/ssato/python-anyconfig/archive/RELEASE_${pkgver}.tar.gz")
sha256sums=('80d51855d1e08999ab2e4e7aec102a78bd02ecbf821911eff5a0e050396e1c2b')

build() {
    cd "${srcdir}/${pkgbase}-RELEASE_${pkgver}"
    python setup.py build
    python2 setup.py build
}


package_python-anyconfig() {
    depends=('python')
    cd "${srcdir}/${pkgbase}-RELEASE_${pkgver}"
    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
    install -Dm644 LICENSE.MIT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-anyconfig() {
    depends=('python2')
    cd "${srcdir}/${pkgbase}-RELEASE_${pkgver}"
    python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
    mv "${pkgdir}/usr/bin/anyconfig_cli" "${pkgdir}/usr/bin/anyconfig_cli2"
    mv "${pkgdir}/usr/share/man/man1/anyconfig_cli.1" "${pkgdir}/usr/share/man/man1/anyconfig_cli2.1"
    install -Dm644 LICENSE.MIT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ft=sh ts=2 sw=2 et: