nowrap - truncates input lines longer than the current terminal width - Usage: cat somefile_with_long_lines.txt | nowrap.pl

nowrap.pl

#!/usr/bin/perl -w

# truncates input lines longer than the current terminal width

# Usage:-
#   cat somefile_with_long_lines.txt | nowrap.pl

use strict;

my $cols=`tput cols`; chomp $cols;

while(<>){
  chompnl($_); my $tmp=$_; my $add=0;
  while($tmp=~/(.*?)(\033\[[\d\;]+m)(.*)/) {
    $add+=length($2) if(length($1)<$cols);      # How much of the string we're about to cut containts non-printing chars
    $tmp=$1 . $3;
  }
  while($tmp=~/(.*?)\t(.*)/) {
    my $spc=8-(length($1) % 8);
    $tmp=$1 . ( ' ' x $spc ) . $2;
    $add-=($spc-1);                             # And how much is tabs too
  }

  my $p=substr($_,0,$cols+$add);
  if($p=~/(\033(?:\[|)[\d\;]{0,})$/) { # cut an escape in half... oops
    $p=substr($p,0,length($p)-length($1));
  }
  print "$p\n";
}

# chomp() on unix doesn't eat "\r"...
sub chompnl {
  chop $_[0] while((substr($_[0],-1) eq "\015")||(substr($_[0],-1) eq "\012"));
} # chompnl

sub reallen {   # Return how big a string was without the ANSI in it
  my($tmp)=@_;
  &chompnl($tmp);
  my $add=0;
  while($tmp=~/(.*?)(\033\[[\d\;]+m)(.*)/) {
    $add+=length($2);
    $tmp=$1 . $3;
  }
  return length($tmp);
}

intelligently handles tabs as well as some ANSI escape sequences (color etc)