simulate multi-layer keyboard

soft-layers.ahk

#inputlevel,2

; Esc | LCtrl
$LCtrl::
    SetMouseDelay -1
    Send {Blind}{LCtrl DownR}
    KeyWait, LCtrl
    Send {Blind}{LCtrl up}
    ; MsgBox, %A_ThisHotkey%-%A_TimeSinceThisHotkey%
    if (A_ThisHotkey="$LCtrl" and A_TimeSinceThisHotkey < 250)
        Send {Blind}{Esc DownR}
    return

; TabFn
$Tab::
    SetMouseDelay -1
    Send {Blind}{F24 DownR}
    KeyWait, Tab
    Send {Blind}{F24 up}
    ; MsgBox, %A_ThisHotkey%-%A_TimeSinceThisHotkey%
    if (A_ThisHotkey="$Tab" and A_TimeSinceThisHotkey < 250)
        Send {Blind}{Tab DownR}
    return

; BackslashFn
$\::
    SetMouseDelay -1
    Send {Blind}{F23 DownR}
    KeyWait, \
    Send {Blind}{F23 up}
    ; MsgBox, %A_ThisHotkey%-%A_TimeSinceThisHotkey%
    if (A_ThisHotkey="$\" and A_TimeSinceThisHotkey < 250)
        Send {Blind}{\ DownR}
    return

#inputlevel,1

; TabFn
F24 & i::Up
F24 & k::Down
F24 & j::Left
F24 & l::Right
F24 & u::PgUp
F24 & o::PgDn
F24 & p::Home
F24 & `;::End
F24 & Backspace::Delete
F24 & '::Pause
F24 & q::F1
F24 & w::F2
F24 & e::F3
F24 & r::F4
F24 & a::F5
F24 & s::F6
F24 & d::F7
F24 & f::F8
F24 & z::F9
F24 & x::F10
F24 & c::F11
F24 & v::F12
F24 & 1::Volume_Down
F24 & 2::Volume_Up
F24 & 3::Media_Play_Pause

; BackslashFn
F23 & q::F1
F23 & w::F2
F23 & e::F3
F23 & r::F4
F23 & a::F5
F23 & s::F6
F23 & d::F7
F23 & f::F8
F23 & z::F9
F23 & x::F10
F23 & c::F11
F23 & v::F12
F23 & g::AppsKey


; fix win10 volume:

$Volume_Up::
    SoundGet, volume
    Send {Volume_Up}
    SoundSet, volume + 4
Return

$Volume_Down::
    SoundGet, volume
    Send {Volume_Down}
    SoundSet, volume - 4
Return