Emojicode - Classes

_main.emojic

📜 🔤customer.emojic🔤
📜 🔤astronaut.emojic🔤
📜 🔤credit_card.emojic🔤
📜 🔤helpers.emojic🔤

🏁 ➡️ 🔢 🍇
  🆕💳 🔤48829284848291🔤 🔤12/24🔤 🔤512🔤❗ ➡️ 🖍️🆕customer_credit_card
  🆕💳 🔤84562234578543🔤 🔤05/27🔤 🔤854🔤❗ ➡️ astronaut_credit_card

  🆕👩‍💼 🔤Frank🔤 🔤Williams🔤 customer_credit_card❗ ➡️ customer
  🆕👩‍🚀 3216 🔤Isabella🔤 🔤Henderson🔤 astronaut_credit_card❗ ➡️ astronaut
  🆕👩‍💼▶️🧜‍♀️ 🔤Ariel🔤 customer_credit_card❗ ➡️ ariel

  💸 astronaut 102.90❗
  🔰🕊️🙏❗
  💸 customer 0.99❗

  🔰🕊️🙏❗
  🖊️ astronaut❗

  🔰🕊️🙏❗
  😀 🔤The customer forgot their security pin (🧲🔑 customer_credit_card❗🧲), so we'll change it.🔤❗
  🗝️ customer_credit_card 🔤123🔤❗ 💭 Change the customer's credit card security code.
  😀 🔤The new security pin has been changed! (🧲🔑 customer_credit_card❗🧲)🔤❗

  ↩️ 0
🍉

astronaut.emojic

🐇 👩‍🚀 👩‍💼 🍇
  🖍️🆕 days_in_space 🔢

  🆕 🍼 days_in_space 🔢 🍼 first_name 🔡 🍼 last_name 🔡 🍼 credit_card 💳 🍇
    ⤴️🆕 first_name last_name credit_card❗
  🍉

  ❓ 🚀 ➡️ 👌 🍇
    ↩️ days_in_space ▶️ 0
  🍉

  ❗ 🚀 days 🔢 🍇
    days ➡️ 🖍️days_in_space
  🍉

  ❗ 🛸 🍇
    ↪️ 🚀👇❓ 🍇
      💸👇 100❗
    🍉
  🍉

  ❗ 🖊️ 🍇
    😀 🔤Astronaut Log:🔤❗
    😀 🔤❌tName: 🧲last_name🧲, 🧲first_name🧲🔤❗
    😀 🔤❌tBeen to Space?: 🧲✏️👇❗🧲🔤❗
    😀 🔤❌tDays in Space: 🧲days_in_space🧲🔤❗
  🍉

  🔒 ❗ ✏️ ➡️ 🔡 🍇
    🔤No🔤 ➡️ 🖍️🆕 been_to_space

    ↪️ 🚀👇❓ 🍇
      🔤Yes🔤 ➡️ 🖍️been_to_space
    🍉

    ↩️ been_to_space
  🍉
🍉

credit_card.emojic

🕊️ 💳 🍇
  🖍️🆕 number 🔡
  🖍️🆕 expiration_date 🔡
  🖍️🆕 security_code 🔡

  🆕 🍼 number 🔡 🍼 expiration_date 🔡 🍼 security_code 🔡 🍇🍉

  ❗ 🔖 ➡️ 🔡 🍇
    ↩️ number
  🍉

  ❗ 🔑 ➡️ 🔡 🍇
    ↩️ security_code
  🍉

  🖍️❗🗝️ code 🔡 🍇
    code ➡️🖍️security_code
  🍉
🍉

customer.emojic

🐇 👩‍💼 🍇
  🖍️🆕 first_name 🔡 ⬅️ 🔤Susan🔤
  🖍️🆕 last_name 🔡 ⬅️ 🔤Rodgers🔤
  🖍️🆕 credit_card 💳 ⬅️ 🆕💳 🔤48829284848291🔤 🔤12/22🔤 🔤513🔤❗

  🆕 🍼 first_name 🔡 🍼 last_name 🔡 🍼 credit_card 💳 🍇🍉

  🆕 ▶️🧜‍♀️ 🍼 first_name 🔡 🍼 credit_card 💳 🍇
    🔤Mermaid🔤 ➡️ 🖍️last_name
  🍉

  ❗ 💸 total 💯 🍇
    😀 🔤Invoice:🔤❗
    😀 🔤❌tTo 🧲first_name🧲 🧲last_name🧲🔤❗
    😀 🔤❌tTotal: 🧲🔡total 2❗🧲🔤❗
    😀 🔤❌tYour credit card will be charged.🔤❗
  🍉
🍉

helpers.emojic

🕊️ 🙏 🍇
  🐇❗ 🔰 🍇
    😀 🔤❌n🔤❗
  🍉

  🐇❗ 🖊️ message 🔡 🍇
    😀 message❗
  🍉
🍉

result.txt

Invoice:
        To: Isabella Henderson
        Total: 102.90
        Your credit card will be charged.


Invoice:
        To: Frank Williams
        Total: 0.99
        Your credit card will be charged.


Astronaut Log:
        Name: Henderson, Isabella
        Been to Space?: Yes
        Days in Space: 3216


The customer forgot their security pin (512), so we'll change it.
The new security pin has been changed! (123)