AUR url-eater-git

PKGBUILD

# Maintainer: Riedler <dev@riedler.wien>
# Maintainer: Mckol <mckol363@gmail.com>

_pkgname=url-eater
pkgname=${_pkgname}-git
pkgver=r3.089835f
pkgrel=1
pkgdesc='Clean unnecessary parameters from URLs copied to clipboard'
provides=("$_pkgname")
conflicts=("$_pkgname")
arch=('any')
url='https://github.com/AgathaSorceress/url-eater'
license=('custom: NVL')
depends=('systemd')
makedepends=('cargo-nightly')
source=(
	"${_pkgname}::git+https://github.com/AgathaSorceress/url-eater.git"
	"default.kdl::https://thermalpaste.technogothic.net/Eh00rL.kdl"
	"url-eater.service"
)
sha256sums=(
	'SKIP'
	'e86c33eb0ef751bfd342734ae2fbf6a15d974948a4f6bd3f45d851da1f5a7fbd'
	'7eb0a4c37f76caad7554c2da76f78d56f25a9f883e3d03d4b1561e7977bdb5f5'
)
backup=('etc/url-eater.kdl')

pkgver() {
	cd "$_pkgname"

  (
    set -o pipefail
    git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

prepare() {
	cd "$_pkgname"

  cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}

build() {
	cd "$_pkgname"

  export RUSTUP_TOOLCHAIN=nightly
  export CARGO_TARGET_DIR=target
  cargo build --release --frozen --all-features
}

package() {
  cd "$_pkgname"

  install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_pkgname"
	install -Dm0644 "$srcdir/default.kdl" "$pkgdir/etc/${_pkgname}.kdl"
	install -Dm0644 -t "$pkgdir/usr/share/${_pkgname}" "$srcdir/default.kdl"
	install -Dm0644 -t "$pkgdir/usr/lib/systemd/user" "$srcdir/${_pkgname}.service"
	install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
}

url-eater.service

[Unit]
Description=Clipboard URL cleanup service
Documentation=https://github.com/AgathaSorceress/url-eater
After=graphical-session-pre.target

[Service]
Type=simple
ExecStart=/usr/bin/url-eater /etc/url-eater.kdl
Restart=on-failure

[Install]
WantedBy=graphical-session.target