PKGBUILD

# Maintainer: Cyrinux <pkgbuilds AT levis DOT name>

_pkgname=firetunnel
pkgname=${_pkgname}-git
pkgver=r77.88d1463
pkgrel=1
pkgdesc="Tunneling program for Firejail sandboxes - git version"
arch=(x86_64)
url="https://github.com/netblue30/firetunnel"
license=(GPL2)
backup=('etc/firetunnel/firetunnel.secret')
makedepends=('git' 'libseccomp')
options=(!emptydirs !strip !zipman)
source=("git+https://github.com/netblue30/firetunnel.git"
    "build-fix.diff::https://github.com/netblue30/firetunnel/pull/3.diff")
sha256sums=('SKIP'
            '31057751fff9c59e3a73b1e124fb607c8cb3b748e6b43106d42691b973bef97e')

pkgver() {
    cd "$_pkgname"

    (
        set -o pipefail
        git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

prepare() {
    cd "$_pkgname"

    # fix build
    git apply -3 ../build-fix.diff
}

build() {
    cd "$_pkgname"

    ./configure --prefix=/usr
    make
}

package() {
    cd "$_pkgname"

    make DESTDIR="$pkgdir" install-strip
}