Get exceptions in org-babel-python when using sessions

ob-babel-python-session-exceptions.el

(defun ob-python--eval-python-session-with-exceptions
    (orig session body &rest args)
  (let* ((exc-file (make-temp-file "session-exception")))
    (unwind-protect
        (let* ((body (format "\
try:
%s
except:
    import traceback
    with open(\"%s\", \"w\") as f:
        f.write(traceback.format_exc())
    raise"
                             (org-babel-python--shift-right body 4)
                             exc-file))
               (result (apply orig session body args))
               (exc-string (with-temp-buffer
                             (insert-file-contents exc-file)
                             (buffer-string))))
          (when (not (string-empty-p exc-string))
            (org-babel-eval-error-notify nil exc-string))
          result)
      (delete-file exc-file))))

(advice-add
 'org-babel-python-evaluate-session
 :around
 #'ob-python--eval-python-session-with-exceptions)