vm-with-nsx-segment.tf

resource "time_sleep" "wait_nsx_segment" {
  depends_on      = [nsxt_policy_fixed_segment.segment1]
  create_duration = "10s"
}

resource "time_sleep" "wait_vm" {
  depends_on      = [vsphere_virtual_machine.vm]
  create_duration = "10s"
}

data "vsphere_datacenter" "datacenter" {
  name = "lab-dc-21"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "lab-cluster-22"
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_datastore" "datastore" {
  name          = "Datastore-NFS-01"
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_network" "network" {
  depends_on = [
    nsxt_policy_fixed_segment.segment1,
    time_sleep.wait_nsx_segment
  ]

  name          = nsxt_policy_fixed_segment.segment1.display_name
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

data "vsphere_virtual_machine" "template" {
  name          = "photon-hw15-5.0-dde71ec57.x86_64"
  datacenter_id = data.vsphere_datacenter.datacenter.id
}

resource "vsphere_virtual_machine" "vm" {
  depends_on = [nsxt_policy_fixed_segment.segment1]

  name             = "vm05"
  resource_pool_id = data.vsphere_compute_cluster.cluster.resource_pool_id
  num_cpus         = 1
  memory           = 1024
  guest_id         = "vmwarePhoton64Guest"
  firmware         = "efi"
  ept_rvi_mode     = "off"
  hv_mode          = "hvOff"
  network_interface {
    network_id = data.vsphere_network.network.id
  }
  datastore_id = data.vsphere_datastore.datastore.id
  disk {
    label = "disk0"
    size  = 16
  }
  clone {
    template_uuid = data.vsphere_virtual_machine.template.id
    linked_clone  = true

    customize {
      network_interface {}
      linux_options {
        host_name = "vm05"
        domain    = "go-lab.jp"
      }
    }
  }
}

output "vm_ip_address" {
  value      = vsphere_virtual_machine.vm.guest_ip_addresses
  depends_on = [time_sleep.wait_vm]
}

下記の投稿むけ。

Terraform で NSX セグメントに vSphere 仮想マシンを接続してみる。https://vm.gowatana.jp/entry/2023/10/25/090031