A ColdBox interceptor that listens for the appropriate Author ORM Interception points announced by CBORM from Hibernate, New function to be injected into every new or loaded Author Object. This new function checks for excluded permissions, before continuing to check permissions via the original ContentBox permission structure.

AuthorORMExtender.cfc

/**
*  Listens for the appropriate Author ORM Interception points announced by CBORM from Hibernate.
*  https://github.com/coldbox-modules/cbox-cborm/wiki/ORM-To-ColdBox-Interceptions
*/
component {

		
	/**
	* Configure Function
	*/
	void function configure(){
		if( !propertyExists( "enabled" ) ){
			setProperty( "enabled", true );
		} 
	}

	
	/**
	* on ORMPostNew, this interceptor injects a new permission check method to wrap the normal check permission method in the Author entity.
	*/
	function ORMPostNew( event, interceptData, buffer, rc, prc ){
		// verify turned on
		if( !getProperty( "enabled" ) ){ return; }

		if( arguments.interceptData.entityName == "cbAuthor" ){
			arguments.interceptData.entity.checkRCPermission = this.checkPermissionPlus;
		}
	}

	
	/**
	* on ORMPostLoad, this interceptor injects a new permission check method to wrap the normal check permission method in the Author entity.
	*/
	function ORMPostLoad( event, interceptData, buffer, rc, prc ){
		// verify turned on
		if( !getProperty( "enabled" ) ){ return; }

		if( arguments.interceptData.entityName == "cbAuthor" ){
			arguments.interceptData.entity.checkRCPermission = this.checkPermissionPlus;
		}
	}


	/**
	* New function to be injected into every new or loaded Author Object.
	* This function checks for excluded permissions, before continuing to check permissions via the original ContentBox permission structure.
	* @permission The permission to be checked 
	*/	
	function checkPermissionPlus( permission='' ){
		if( arguments.permission == "GLOBAL_SEARCH" ){
			return false;
		}
		return checkPermission( arguments.permission );
	}
	
}