gistfile1.txt

{ stdenv }:
{ name, script, bundlerEnvResult }:
stdenv.mkDerivation {
  inherit name;

  # The normal bundler wrapper uses a script in a shebang. This works
  # fine on Linux, but OSX's kernel doesn't permit this.
  #
  # This wrapper copies the wrappedRuby script, which ends in:
  #
  #   exec /nix/store/...-ruby-2.3.3/bin/ruby "${extraFlagsArray[@]}" "$@"
  #
  # and adds the script between `bin/ruby` and `"${extraFlagsArray`:
  #
  #   exec /nix/store/...-ruby-2.3.3/bin/ruby /nix/store/...-my-script "${extraFlagsArray[@]}" "$@"
  #
  # and since the wrappedRuby script uses bash directly in the
  # shebang (and not another script) this works on macOS and Linux.
  buildCommand = ''
    sed \
      -e "s#/bin/ruby\" #/bin/ruby\" ${script} #" \
      ${bundlerEnvResult.wrappedRuby}/bin/ruby > ./working

    if ! grep -q "${script}" ./working; then
      echo " ABORTING:"
      echo "    sed appears to not have correctly added the script on"
      echo "    the exec line, which breaks this tool."
      exit 1
    fi

    mkdir -p $out/bin
    install -D -m755 ./working $out/bin/${name}
  '';

  passthru.env = bundlerEnvResult;
}