docker_compose 1.18.0 latest nixpkgs override overlay

docker-compose-overlay.nix

self: super:

{
  python = let packageOverrides = pythonSelf: pythonSuper: {
    docker = pythonSuper.docker.overridePythonAttrs (oldAttrs: rec {
      name = "docker-2.7.0";

      src = super.fetchurl {
        url = "mirror://pypi/d/docker/${name}.tar.gz";
        sha256 = "0v57sqhbjfiinzkhy7dnj30pryfsaldlxmy6cd41r8wfiqq4hhhl";
      };
    });

    texttable = pythonSuper.texttable.overridePythonAttrs (oldAttrs: rec {
      name = "texttable-1.1.1";

      src = super.fetchurl {
        url = "mirror://pypi/t/texttable/${name}.tar.gz";
        sha256 = "174wfxbq0kssvm9l95bvdl3a0g26fi5s9syiqijc57qa8wflsrs4";
      };
    });
  }; in super.python.override { inherit packageOverrides; };

  docker_compose = super.docker_compose.overridePythonAttrs (oldAttrs: rec {
    name = "docker-compose-1.18.0";

    src = self.fetchurl {
       url = "mirror://pypi/d/docker-compose/${name}.tar.gz";
       sha256 = "0yfka41raqrg44a3yyvianciv1l8camh0xipfnxqy0c54vzcnc19";
    };
  });
}

Tested on channel nixos-17.09.

The above is a nixpkgs overlay that allows you to install docker-compose 1.18.0

Usage

• Place the above in ~/.config/nixpkgs/overlays/docker-compose-overlay.nix

• Run nix-env -iA nixos.docker_compose

• Confirm that docker-compose 1.18.0 is installed with docker-compose --version