Extract a Firefox session cookie

extract-session-cookie.pl

#!/usr/bin/env perl
use strict;
use warnings;
use 5.010;

use Compress::LZ4;
use JSON::MaybeXS;
use Path::Tiny;

# Firefox doesn't store session cookies in the sqlite database, so
# HTTP::Cookies::Mozilla won't find them.
# This method only works if sessionstore hasn't been disabled.
# Firefox 56 switched to using lz4-compressed files.

# Adjust the path depending upon OS.
my $pat = '~/Library/Application\ Support/Firefox/Profiles/*.default*'
    . '/sessionstore-backups/recovery.js';
my ($prof, $sess);
if ($prof = glob "${pat}onlz4") {
    my $bytes = path($prof)->slurp;
    substr $bytes, 0, 8, '';  # Remove mozLz4\0 header
    $sess = eval { decode_json decompress $bytes };
}
elsif ($prof = glob $pat) {
    $sess = eval { decode_json path($prof)->slurp };
}
else { die 'no recovery file found' }

my @cookie;
for my $cookie (@{ $sess->{cookies} }) {
    # next unless $cookie->{host} =~ /\.?example\.com$/i;
    my $name = $cookie->{name} // '';
    next unless 'PHPSESSID' eq $name;
    $cookie->{host} =~ s/^\.//;
    push @cookie, $cookie;
}

die 'no session cookie found' unless @cookie;

# Use the extracted cookie.
use LWP::UserAgent;
my $ua = LWP::UserAgent->new(cookie_jar => {});
for my $cookie (@cookie) {
    $ua->cookie_jar->set_cookie(0, $cookie->@{qw(name value path host)});
}