geeqie-git example

PKGBUILD

# Maintainer: Steven Honeyman <stevenhoneyman at gmail com>
# Contributor: graysky <graysky AT archlinux DOT us>
# COntributor: Eric Bélanger <eric@archlinux.org>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>

pkgname=geeqie-git
pkgver=r2784.a85944bb
pkgrel=1
pkgdesc='Lightweight image viewer'
arch=('x86_64')
url="http://www.geeqie.org/"
license=('GPL2')
depends=('exiv2' 'gtk2' 'ffmpegthumbnailer' 'libheif')
makedepends=('intltool' 'doxygen' 'gnome-doc-utils' 'python' 'git')
optdepends=('librsvg: SVG rendering'
            'fbida: for jpeg rotation')
provides=('geeqie')
conflicts=('geeqie' 'gqview-devel')
source=(git://github.com/BestImageViewer/geeqie.git#branch=master
        'geeqie-no-changelog.patch')
sha256sums=('SKIP'
            'f6eb2725a47fc750d95455d4bbf4be5a0ae45307d3ada571937212a25b2b4301')

pkgver() {
  cd geeqie
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd geeqie
  patch -p1 -i ../geeqie-no-changelog.patch # Workaround missing changelog (Fedora)
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd geeqie
  ./configure --prefix=/usr
  make
}

package(){
  cd geeqie
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: