it87-dkms-git cleaned

PKGBUILD

# Maintainer: Daniel Hillenbrand <codeworkx at bbqlinux dot org>
# Contributer: Hanabishi
# Contributer: graysky <therealgraysky AT proton DOT me>

pkgbase=it87
pkgname=(
  $pkgbase-dkms-git
  $pkgbase-dkms-git-docs
)
pkgver=236.6392311
pkgrel=1
pkgdesc="Linux Driver for ITE LPC chips"
arch=('x86_64')
url="https://github.com/frankcrawford/it87"
license=('GPL')
depends=('dkms')
makedepends=('git')
provides=('it87')
conflicts=('it87-frankcrawford-dkms-git')

source=("$pkgbase::git+https://github.com/frankcrawford/it87.git"
        "dkms.conf")

sha256sums=('SKIP'
            'f325b751c8a81416a75c2c1e7a7bc9ca46ae0fa3b44d4ccc09593274be1b2dc7')

pkgver() {
  cd "$srcdir/$pkgbase"
  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$pkgbase"
}

package_it87-dkms-git() {
  cd "$srcdir/$pkgbase"

  install -d "$pkgdir"/usr/src/$pkgbase-$pkgver/

  install -Dm644 "$srcdir"/dkms.conf 'compat.h' 'it87.c' 'Makefile' -t "$pkgdir"/usr/src/$pkgbase-$pkgver

  sed -e "s/@_PKGBASE@/$pkgbase/" \
    -e "s/@PKGVER@/$pkgver/" \
    -i "$pkgdir"/usr/src/$pkgbase-$pkgver/dkms.conf
  
  install -Dm644 'Sensors configs'/* -t "$pkgdir"/usr/share/it87/configs
}

package_it87-dkms-git-docs() {
  cd "$srcdir/$pkgbase"

  install -Dm644 'README' 'ISSUES' -t "$pkgdir"/usr/share/doc/$pkgname
  cp -rd 'Research' -t "$pkgdir"/usr/share/doc/$pkgname
}

do you plan to update the aur with this?

I do not own the package in the AUR. I can only make the suggestion.

Package owner here, think I did not see the comment. I see a number of changes, but I'm not sure I know exactly why there were all made.

Mirror of AUR repo is available at https://github.com/codebling/arch-it87-frankcrawford-dkms-git if you submit a pull request there it will be easier to track the discussion.

It looks like this was turned into a multipackage but I have some questions about that too