Reading linq2db configuration from json

Configuration.fs

module Configuration

open System
open System.IO
open Microsoft.Extensions.Configuration
open Microsoft.Extensions.Configuration.Binder
open Microsoft.Extensions.Configuration.Json
open LinqToDB.Configuration

let [<Literal>] private SqlServer = "SqlServer"

[<CLIMutable>]
type DBConfiguration =
    {   ConnectionString: string
        Name: string
        ProviderName: string
    }
    static member Default =
        {   ConnectionString = String.Empty
            Name = String.Empty
            ProviderName = String.Empty
        }
    member this.AsSettings () =
        { new IConnectionStringSettings with
            member __.ConnectionString with get() = this.ConnectionString
            member __.Name with get() = this.Name
            member __.ProviderName with get() = this.ProviderName
            member __.IsGlobal with get() = false
        }

type DBSettings (file: string, [<ParamArray>] sections: string array) =
    let configurations =
        let cfgBuilder =
            ConfigurationBuilder()
                .SetBasePath(Directory.GetCurrentDirectory())
                .AddJsonFile(file)
                .Build()

        sections
        |> Array.map (fun s ->
            let cfg = DBConfiguration.Default
            cfgBuilder.GetSection(s).Bind(cfg)
            cfg.AsSettings()
        )
        |> Seq.ofArray
        |> Seq.cache

    interface ILinqToDBSettings with
        member val DataProviders = Seq.empty
        member val DefaultDataProvider = SqlServer
        member val DefaultConfiguration = SqlServer
        member val ConnectionStrings = configurations