Code to run WiFi in AP mode while running a simple webserver at the same time on an ESP32 Feather Board from Adafruit

Adadfruit HUZZAH32 ESP32 Feather Board softAP and webserver.ino

#include <WiFi.h>

WiFiServer server(80);
const int LED_PIN = 13;

void setup()
{
  
  initHardware();
  setupWiFi();
  Serial.println("Starting WebServer");
  server.begin();
  Serial.println("Webserver Started");
}

void loop()
{
  webserverLoop();
}

void initHardware() {
  pinMode(LED_PIN, OUTPUT);
  Serial.begin(9600);
}

void setupWiFi() {
  Serial.println("Setting WiFi Mode: WIFI_AP");
  WiFi.mode(WIFI_AP);

  Serial.println("Starting AP...");
  bool success = WiFi.softAP("esp32", "12345678");

  if(success) {
    Serial.println("AP Started");
    Serial.println(WiFi.softAPIP());
  } else {
    Serial.println("AP Setup Failed");
  }
}

void webserverLoop() {
 WiFiClient client = server.available();   // listen for incoming clients

  if (client) {                             // if you get a client,
    Serial.println("New Client.");           // print a message out the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        if (c == '\n') {                    // if the byte is a newline character

          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println();

            // the content of the HTTP response follows the header:
            client.print("Click <a href=\"/H\">here</a> to turn the LED on pin 13 on.<br>");
            client.print("Click <a href=\"/L\">here</a> to turn the LED on pin 13 off.<br>");

            // The HTTP response ends with another blank line:
            client.println();
            // break out of the while loop:
            break;
          } else {    // if you got a newline, then clear currentLine:
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }

        // Check to see if the client request was "GET /H" or "GET /L":
        if (currentLine.endsWith("GET /H")) {
          digitalWrite(LED_PIN, HIGH);               // GET /H turns the LED on
        }
        if (currentLine.endsWith("GET /L")) {
          digitalWrite(LED_PIN, LOW);                // GET /L turns the LED off
        }
      }
    }
    // close the connection:
    client.stop();
    Serial.println("Client Disconnected.");
  }
}