moonphase.pl

#!/usr/bin/perl -I /home/gustaf/perl5-OLD/lib/perl5/

use strict;
use warnings;
use Astro::MoonPhase;
binmode( STDOUT, ":utf8" );

sub moon_info {
    my ($epoch) = @_;
    my ( $MoonPhase, $MoonIllum, $MoonAge, $MoonDist,
         $MoonAng,   $SunDist,   $SunAng ) = phase($epoch);
    return [ $MoonPhase, $MoonIllum, $MoonAge ];
}

sub phase_name {
    my ( $phase, $illum ) = @_;
    my $string = '';
    if ( $phase < 0.25 ) { $string = 'WaxC' }
    elsif ( $phase >= 0.25 and $phase < 0.5 )  { $string = 'WaxG' }
    elsif ( $phase >= 0.5  and $phase < 0.75 ) { $string = 'WanG' }
    elsif ( $phase >= 0.75 ) { $string = 'WanC' }

    if ( $illum <= 0.01 ) { return 'NewM' }
    if ( $illum >= 0.99 ) { return 'Full' }
    if ( abs( $illum - 0.5 ) <= 0.01 and $string =~ m/Wax/ ) { return "1Q" }
    if ( abs( $illum - 0.5 ) <= 0.01 and $string =~ m/Wan/ ) { return "3Q" }

    return $string;
}

sub phase_emoji {

    # https://gist.github.com/ddrscott/5339084

    # phases = 🌑  🌒  🌓  🌔  🌕  🌖  🌗  🌘
    # U+1F311 🌑 NEW MOON SYMBOL
    # U+1f312 🌒 WAXING CRESCENT MOON SYMBOL
    # U+1f313 🌓 FIRST QUARTER MOON SYMBOL
    # U+1f314 🌔 WAXING GIBBOUS MOON SYMBOL
    # U+1f315 🌕 FULL MOON SYMBOL
    # U+1f316 🌖 WANING GIBBOUS MOON SYMBOL
    # U+1f317 🌗 LAST QUARTER MOON SYMBOL
    # U+1f318 🌘 WANING CRESCENT MOON SYMBOL

    my ( $phase, $illum ) = @_;
    my $string = '';
    my $curr_phase;
    if ( $phase < 0.25 ) {
	$string = "\x{1f312}"; # Waxing crescent - 🌒
	$curr_phase = 'Wax';
    } 
    elsif ( $phase >= 0.25 and $phase < 0.5 )  {
	$string = "\x{1f314}"; #  Waxing gibbous - 🌔
	$curr_phase = 'Wax';
    }
    elsif ( $phase >= 0.5  and $phase < 0.75 ) {
	$string = "\x{1f316}"; #  Waning gibbous - 🌖
	$curr_phase = 'Wan';
    }
    elsif ( $phase >= 0.75 ) {
	$string = "\x{1f318}"; # Waning crescent - 🌘
	$curr_phase = 'Wan';
    }
    if ( $illum <= 0.01 ) {
	$string = "\x{1f311}"; #  new moon - 🌑
	$curr_phase='Wax';
    }
    if ( $illum >= 0.99 ) {
	$string= "\x{1f315}"; # full moon - 🌕
	$curr_phase = 'Wan';
    }
    if ( abs( $illum - 0.5 ) <= 0.01 and $curr_phase =~ m/Wax/ ) {
	$string = "\x{1f313}"; # first quarter - 🌓
    }
    if ( abs( $illum - 0.5 ) <= 0.01 and $curr_phase =~ m/Wan/ ) {
        $string = "\x{1f317}"; # 3rd quarter - 🌗
    }
    return $string;
}

my $now  = shift || time;
my $info = moon_info($now);

#my $name = phase_name($info->[0],$info->[1]);
my $name  = phase_emoji( $info->[0], $info->[1] );
my $illum = $info->[1];
my $age   = $info->[2];

printf( "%s %.0f%% %.2f\n", $name, $illum * 100, $age );