h-east/gen_syntax_vim.patch

## gen_syntax_vim.patch
diff --git a/src/Makefile b/src/Makefile
--- a/src/Makefile
+++ b/src/Makefile
@@ -1515,6 +1515,9 @@
 UNITTEST_SRC = $(MEMFILE_TEST_SRC)
 UNITTEST_TARGETS = $(MEMFILE_TEST_TARGET)

+# syntax/vim.vim generator & Vim source code sanity checker
+GEN_SYN_VIM_DIR = gen_syntax_vim
+
 # All sources, also the ones that are not configured
 ALL_SRC = $(BASIC_SRC) $(ALL_GUI_SRC) $(UNITTEST_SRC) $(EXTRA_SRC)

@@ -1666,7 +1669,7 @@
 	os_mswin.pro winclip.pro os_beos.pro os_vms.pro $(PERL_PRO)

 # Default target is making the executable and tools
-all: $(VIMTARGET) $(TOOLS) languages $(GUI_BUNDLE)
+all: $(VIMTARGET) $(TOOLS) languages $(GUI_BUNDLE) generator

 tools: $(TOOLS)

@@ -1779,6 +1782,10 @@
 update-po:
 	cd $(PODIR); CC="$(CC)" $(MAKE) prefix=$(DESTDIR)$(prefix) update-po

+# Update the syntax/vim.vim, when changes the relevant source code.
+generator:
+	@$(MAKE) -C $(GEN_SYN_VIM_DIR) update
+
 # Generate function prototypes.  This is not needed to compile vim, but if
 # you want to use it, cproto is out there on the net somewhere -- Webb
 #
@@ -2413,6 +2420,7 @@
 	-rm -f runtime pixmaps
 	-rm -rf $(APPDIR)
 	-rm -rf mzscheme_base.c
+	-$(MAKE) -C $(GEN_SYN_VIM_DIR) clean
 	if test -d $(PODIR); then \
 		cd $(PODIR); $(MAKE) prefix=$(DESTDIR)$(prefix) clean; \
 	fi
diff --git a/src/gen_syntax_vim/Makefile b/src/gen_syntax_vim/Makefile
new file mode 100644
--- /dev/null
+++ b/src/gen_syntax_vim/Makefile
@@ -0,0 +1,57 @@
+#
+# Makefile to update runtime/syntax/vim.vim
+#
+# - First, Generate vim.vim.rc that is Release Candidate file to copy
+#   runtime/syntax/vim.vim
+# - vim.vim.rc is based on vim.vim.base and created from parses some source
+#   code of Vim.
+# - If different vim.vim.rc and runtime/syntax/vim.vim, Update the date
+#   information of vim.vim.rc and copy it to runtime/syntax/vim.vim.
+
+VIMPROG = ../vim
+SYN_VIM_VIM = ../../runtime/syntax/vim.vim
+
+SCRIPTS = gen_syntax_vim.vim update_date.vim
+
+.PHONY: update clean eval_check
+
+RM_ON_COMMON = chk_src chk_dst
+RM_ON_START = $(RM_ON_COMMON) sanity_check.err generator.err
+RM_ON_END = $(RM_ON_COMMON) noeval
+RUN_VIM = $(VIMPROG) -N -u NONE -i NONE -n
+EXCLUDE_PTN = "^\" Last Change:"
+
+update: eval_check vim.vim.rc
+
+clean:
+	-@rm -f $(RM_ON_END) vim.vim.rc
+
+vim.vim.rc: $(VIMPROG) $(SCRIPTS) vim.vim.base
+	-@rm -f $(RM_ON_START)
+	@if ! test -f noeval; then \
+		$(RUN_VIM) -c "so gen_syntax_vim.vim"; \
+		if test -f sanity_check.err; then \
+			echo; \
+			echo Vim sanity check Error; \
+			cat sanity_check.err; \
+			-rm -f $(VIMPROG); \
+			exit 1; \
+		fi; \
+		if test -f generator.err; then \
+			echo Generator Error; \
+			cat generator.err; \
+		else \
+			grep -v $(EXCLUDE_PTN) vim.vim.rc > chk_src; \
+			grep -v $(EXCLUDE_PTN) $(SYN_VIM_VIM) > chk_dst; \
+			if ! diff -q chk_src chk_dst > /dev/null; then \
+				$(RUN_VIM) -s update_date.vim; \
+				cp -f vim.vim.rc $(SYN_VIM_VIM); \
+				echo Update $(SYN_VIM_VIM); \
+			fi; \
+		fi; \
+	fi
+	-@rm -f $(RM_ON_END)
+
+eval_check: eval_check.vim
+	-@rm -f noeval
+	@$(RUN_VIM) -s eval_check.vim
diff --git a/src/gen_syntax_vim/eval_check.vim b/src/gen_syntax_vim/eval_check.vim
new file mode 100644
--- /dev/null
+++ b/src/gen_syntax_vim/eval_check.vim
@@ -0,0 +1,5 @@
+:" If +eval feature supported quit here, No create 'noeval' file.
+:" Otherwise create 'noeval' file.
+:if 1 | q! | endif
+:w! noeval
+:qa!
diff --git a/src/gen_syntax_vim/gen_syntax_vim.vim b/src/gen_syntax_vim/gen_syntax_vim.vim
new file mode 100644
--- /dev/null
+++ b/src/gen_syntax_vim/gen_syntax_vim.vim
@@ -0,0 +1,563 @@
+" Vim syntax file generator
+" Language: Vim 7.4 script
+" Maintainer: Hirohito Higashi
+" Last Change: OCT 10, 2015
+" Version: 0.0.1
+
+let s:keepcpo= &cpo
+set cpo&vim
+
+language C
+
+function! s:parse_vim_option(opt, missing_opt, term_out_code)
+	try
+		let file_name = '../option.c'
+		let item = {}
+
+		new
+		exec 'read ' . file_name
+		norm! gg
+		exec '/^\s*options\[\]\s*=\s*$/+1;/^\s*#\s*define\s*p_term(/-1yank a'
+		exec '/^#define\s\+p_term(/+1;/^};$/-1yank b'
+		%delete _
+
+		put a
+		" workaround for 'shortname'
+		g/^#\s*ifdef\s*SHORT_FNAME\>/j
+		g/^#/d
+		g/^\s*{\s*"\w\+"\%(\s*,\s*[^,]*\)\{2}[^,]$/j
+		g/^\s*{\s*"\w\+"\s*,.*$/j
+		g!/^\s*{\s*"\w\+"\s*,.*$/d
+
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*{\s*"\(\w\+\)"\s*,\s*\%("\(\w\+\)"\|NULL\)\s*,\s*\%([^,]*\(P_BOOL\)[^,]*\|[^,]*\)\s*,\s*\([^,]*NULL\)\?.*')
+			let item.name = list[1]
+			let item.short_name = list[2]
+			let item.is_bool = empty(list[3]) ? 0 : 1
+			if empty(list[4])
+				call add(a:opt, copy(item))
+			else
+				call add(a:missing_opt, copy(item))
+			endif
+		endfor
+		if empty(a:opt)
+			throw 'opt is empty'
+		endif
+		if empty(a:missing_opt)
+			throw 'missing_opt is empty'
+		endif
+
+		%delete _
+		put b
+		g!/^\s*p_term(\s*"\w\+"\s*,.*$/d
+
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*p_term(\s*"\(\w\+\)"\s*,')
+			let item.name = list[1]
+			call add(a:term_out_code, copy(item))
+		endfor
+		quit!
+		if empty(a:term_out_code)
+			throw 'term_out_code is empty'
+		endif
+	catch /.*/
+		call s:err_gen('')
+		throw 'exit'
+	endtry
+endfunc
+
+function! s:append_syn_vimopt(lnum, str_info, opt_list, prefix, bool_only)
+	let ret_lnum = a:lnum
+	let str = a:str_info.start
+
+	for o in a:opt_list
+		if !a:bool_only || o.is_bool
+			if !empty(o.short_name)
+				let str .= ' ' . a:prefix . o.short_name
+			endif
+			let str .= ' ' . a:prefix . o.name
+			if len(str) > s:line_break_len
+				if !empty(a:str_info.end)
+					let str .= ' ' . a:str_info.end
+				endif
+				call append(ret_lnum, str)
+				let str = a:str_info.start
+				let ret_lnum += 1
+			endif
+		endif
+	endfor
+	if str !=# a:str_info.start
+		if !empty(a:str_info.end)
+			let str .= ' ' . a:str_info.end
+		endif
+		call append(ret_lnum, str)
+		let ret_lnum += 1
+	endif
+	return ret_lnum
+endfunc
+
+" ------------------------------------------------------------------------------
+function! s:parse_vim_command(cmd)
+	try
+		let file_name = '../ex_cmds.h'
+		let item = {}
+
+		new
+		exec 'read ' . file_name
+		norm! gg
+		exec '/^\s*cmdnames\[\]\s*=\s*$/+1;/^};/-1yank'
+		%delete _
+		put
+		g!/^EX(/d
+
+		let lcmd = {}
+		for key in range(char2nr('a'), char2nr('z'))
+			let lcmd[nr2char(key)] = []
+		endfor
+		let lcmd['~'] = []
+
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^EX(\w\+\s*,\s*"\(\a\w*\)"\s*,')
+			if !empty(list)
+				" Small ascii character or other.
+				let key = (list[1][:0] =~# '\l') ? list[1][:0] : '~'
+				call add(lcmd[key], list[1])
+			endif
+		endfor
+		quit!
+
+		for key in sort(keys(lcmd))
+			for my in range(len(lcmd[key]))
+				let omit_idx = 0
+				if my > 0
+					let omit_idx = (key =~# '\l') ? 1 : 0
+					for idx in range(1, strlen(lcmd[key][my]))
+						let matched = 0
+						for pre in range(my - 1, 0, -1)
+							if pre == my
+								continue
+							endif
+							" for wired abbreviations for delete. (See :help :d)
+							if lcmd[key][my][:idx] ==# lcmd[key][pre][:idx] ||
+							\	(key ==# 'd' &&
+							\		lcmd[key][my][:idx] =~# '^d\%[elete][lp]$')
+								let matched = 1
+								let omit_idx = idx + 1
+								break
+							endif
+						endfor
+						if !matched
+							break
+						endif
+					endfor
+				endif
+
+				let item.name = lcmd[key][my]
+				let item.type = s:get_vim_command_type(item.name)
+				if omit_idx + 1 < strlen(item.name)
+					let item.syn_str = item.name[:omit_idx] . '[' .
+					\		item.name[omit_idx+1:] . ']'
+				else
+					let item.syn_str = item.name
+				endif
+				call add(a:cmd, copy(item))
+			endfor
+		endfor
+
+		" Add wired abbreviations for delete. (See :help :d)
+		for i in ['l', 'p']
+			let str = 'delete'
+			let item.name = str . i
+			let item.type = s:get_vim_command_type(item.name)
+			for x in range(strlen(str))
+				let item.syn_str = str[:x] . i
+				if item.syn_str !=# "del"
+					call add(a:cmd, copy(item))
+				endif
+			endfor
+		endfor
+
+		if empty(a:cmd)
+			throw 'cmd is empty'
+		endif
+	catch /.*/
+		call s:err_gen('')
+		throw 'exit'
+	endtry
+endfunc
+
+function! s:get_vim_command_type(cmd_name)
+	let map_prefix = '^[anvxsoilc]\?'
+	" 0: normal
+	" 1: let / unlet
+	" 2: abbrev (without un)
+	" 3: menu
+	" 4: map
+	" 5: mapclear
+	" 6: unmap
+
+	" TODO: behave, augroup, autocmd
+	if a:cmd_name =~# '^\%(un\)\?let$'
+		let ret = 1
+	elseif a:cmd_name =~# '^\%(abbreviate\|noreabbrev\|\l\%(nore\)\?abbrev\)$'
+		let ret = 2
+	elseif a:cmd_name =~# '^[anovxsic]\?\%(nore\|un\)\?menu$'
+		let ret = 3
+	elseif a:cmd_name =~# map_prefix . '\%(nore\)\?map$'
+		let ret = 4
+	elseif a:cmd_name =~# map_prefix . 'mapclear$'
+		let ret = 5
+	elseif a:cmd_name =~# map_prefix . 'unmap$'
+		let ret = 6
+	else
+		let ret = 0
+	endif
+	return ret
+endfunc
+
+function! s:append_syn_vimcmd(lnum, str_info, cmd_list, type)
+	let ret_lnum = a:lnum
+	let str = a:str_info.start
+
+	for o in a:cmd_list
+		if o.type == a:type
+			let str .= ' ' . o.syn_str
+			if len(str) > s:line_break_len
+				if !empty(a:str_info.end)
+					let str .= ' ' . a:str_info.end
+				endif
+				call append(ret_lnum, str)
+				let str = a:str_info.start
+				let ret_lnum += 1
+			endif
+		endif
+	endfor
+	if str !=# a:str_info.start
+		if !empty(a:str_info.end)
+			let str .= ' ' . a:str_info.end
+		endif
+		call append(ret_lnum, str)
+		let ret_lnum += 1
+	endif
+	return ret_lnum
+endfunc
+
+" ------------------------------------------------------------------------------
+function! s:parse_vim_event(li)
+	try
+		let file_name = '../fileio.c'
+		let item = {}
+
+		new
+		exec 'read ' . file_name
+		norm! gg
+		exec '/^}\s*event_names\[\]\s*=\s*$/+1;/^};/-1yank'
+		%delete _
+
+		put
+		g!/^\s*{\s*"\w\+"\s*,.*$/d
+
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*{\s*"\(\w\+\)"\s*,')
+			let item.name = list[1]
+			call add(a:li, copy(item))
+		endfor
+
+		quit!
+
+		if empty(a:li)
+			throw 'event is empty'
+		endif
+	catch /.*/
+		call s:err_gen('')
+		throw 'exit'
+	endtry
+endfunc
+
+" ------------------------------------------------------------------------------
+function! s:parse_vim_function(li)
+	try
+		let file_name = '../eval.c'
+		let item = {}
+
+		new
+		exec 'read ' . file_name
+		norm! gg
+		exec '/^}\s*functions\[\]\s*=\s*$/+1;/^};/-1yank'
+		%delete _
+
+		put
+		g!/^\s*{\s*"\w\+"\s*,.*$/d
+		g/^\s*{\s*"test"\s*,.*$/d
+		g@/\*\s*obsolete\s*\*/@d
+
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*{\s*"\(\w\+\)"\s*,')
+			let item.name = list[1]
+			call add(a:li, copy(item))
+		endfor
+
+		quit!
+
+		if empty(a:li)
+			throw 'function is empty'
+		endif
+	catch /.*/
+		call s:err_gen('')
+		throw 'exit'
+	endtry
+endfunc
+
+" ------------------------------------------------------------------------------
+function! s:parse_vim_hlgroup(li)
+	try
+		let file_name = '../syntax.c'
+		let item = {}
+
+		new
+		exec 'read ' . file_name
+		call cursor(1, 1)
+		exec '/^static\s\+char\s\+\*(highlight_init_both\[\])\s*=$/+1;/^\s*};/-1yank a'
+		exec '/^static\s\+char\s\+\*(highlight_init_light\[\])\s*=$/+1;/^\s*};/-1yank b'
+		"exec '/^static\s\+char\s\+\*(highlight_init_dark\[\])\s*=$/+1;/^\s*};/-1yank c'
+		exec '/^set_normal_colors()$/+1;/^}$/-1yank d'
+		%delete _
+		put a
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*"\(\w\+\)[^"]*")\?,')
+			if !empty(list)
+				let item.name = list[1]
+				let item.type = 'both'
+				call add(a:li, copy(item))
+			endif
+		endfor
+
+		%delete _
+		put b
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*"\(\w\+\)[^"]*")\?,')
+			if !empty(list)
+				let item.name = list[1]
+				let item.type = 'light'
+				call add(a:li, copy(item))
+			endif
+		endfor
+
+		%delete _
+		put d
+		for line in getline(1, line('$'))
+			let list = matchlist(line, '^\s*if\s*(set_group_colors(.*"\(\w\+\)",')
+			if !empty(list) && list[1] !=# 'Normal'
+				let item.name = list[1]
+				let item.type = 'gui'
+				call add(a:li, copy(item))
+			endif
+		endfor
+
+		let item.name = 'CursorIM'
+		let item.type = 'gui'
+		call add(a:li, copy(item))
+
+		quit!
+
+		if empty(a:li)
+			throw 'hlgroup is empty'
+		endif
+	catch /.*/
+		call s:err_gen('')
+		throw 'exit'
+	endtry
+endfunc
+
+" ------------------------------------------------------------------------------
+function! s:append_syn_any(lnum, str_info, li)
+	let ret_lnum = a:lnum
+	let str = a:str_info.start
+
+	for o in a:li
+		let str .= ' ' . o.name
+		if len(str) > s:line_break_len
+			if !empty(a:str_info.end)
+				let str .= ' ' . a:str_info.end
+			endif
+			call append(ret_lnum, str)
+			let str = a:str_info.start
+			let ret_lnum += 1
+		endif
+	endfor
+	if str !=# a:str_info.start
+		if !empty(a:str_info.end)
+			let str .= ' ' . a:str_info.end
+		endif
+		call append(ret_lnum, str)
+		let ret_lnum += 1
+	endif
+	return ret_lnum
+endfunc
+
+function! s:update_syntax_vim_file(vim_info)
+	try
+		function! s:search_and_check(kword, base_fname, str_info)
+			let a:str_info.start = ''
+			let a:str_info.end = ''
+
+			let pattern = '^" GEN_SYN_VIM: ' . a:kword . '\s*,'
+			let lnum = search(pattern)
+			if lnum == 0
+				throw 'Search pattern ''' . pattern . ''' not found in ' .
+				\		a:base_fname
+			endif
+			let li = matchlist(getline(lnum), pattern . '\s*START_STR\s*=\s*''\(.\{-}\)''\s*,\s*END_STR\s*=\s*''\(.\{-}\)''')
+			if empty(li)
+				throw 'Bad str_indo line:' . getline(lnum)
+			endif
+			let a:str_info.start = li[1]
+			let a:str_info.end = li[2]
+			return lnum
+		endfunc
+
+		let target_fname = 'vim.vim.rc'
+		let base_fname = 'vim.vim.base'
+		let str_info = {}
+		let str_info.start = ''
+		let str_info.end = ''
+
+		new
+		exec 'edit ' . target_fname
+		%d _
+		exec 'read ' . base_fname
+		1delete _
+		call cursor(1, 1)
+
+		" vimCommand
+		let li = a:vim_info.cmd
+		" vimCommand - normal
+		let lnum = s:search_and_check('vimCommand normal', base_fname, str_info)
+		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 0)
+
+		" vimOption
+		let kword = 'vimOption'
+		let li = a:vim_info.opt
+		" vimOption - normal
+		let lnum = s:search_and_check(kword . ' normal', base_fname, str_info)
+		let lnum = s:append_syn_vimopt(lnum, str_info, li, '', 0)
+		" vimOption - turn-off
+		let lnum = s:search_and_check(kword . ' turn-off', base_fname, str_info)
+		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'no', 1)
+		" vimOption - invertible
+		let lnum = s:search_and_check(kword . ' invertible', base_fname, str_info)
+		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'inv', 1)
+		" vimOption - term output code
+		let li = a:vim_info.term_out_code
+		let lnum = s:search_and_check(kword . ' term output code', base_fname, str_info)
+		let lnum = s:append_syn_any(lnum, str_info, li)
+
+		" Missing vimOption
+		let li = a:vim_info.missing_opt
+		let lnum = s:search_and_check('Missing vimOption', base_fname, str_info)
+		let lnum = s:append_syn_vimopt(lnum, str_info, li, '', 0)
+		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'no', 1)
+		let lnum = s:append_syn_vimopt(lnum, str_info, li, 'inv', 1)
+
+		" vimAutoEvent
+		let li = a:vim_info.event
+		let lnum = s:search_and_check('vimAutoEvent', base_fname, str_info)
+		let lnum = s:append_syn_any(lnum, str_info, li)
+
+		" vimHLGroup
+		let li = a:vim_info.hlgroup
+		let lnum = s:search_and_check('vimHLGroup', base_fname, str_info)
+		let lnum = s:append_syn_any(lnum, str_info, li)
+
+		" vimFuncName
+		let li = a:vim_info.func
+		let lnum = s:search_and_check('vimFuncName', base_fname, str_info)
+		let lnum = s:append_syn_any(lnum, str_info, li)
+
+		" vimCommand - abbrev
+		let kword = 'vimCommand'
+		let li = a:vim_info.cmd
+		let lnum = s:search_and_check(kword . ' abbrev', base_fname, str_info)
+		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 2)
+		" vimCommand - map
+		let lnum = s:search_and_check(kword . ' map', base_fname, str_info)
+		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 4)
+		let lnum = s:search_and_check(kword . ' mapclear', base_fname, str_info)
+		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 5)
+		let lnum = s:search_and_check(kword . ' unmap', base_fname, str_info)
+		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 6)
+		" vimCommand - menu
+		let lnum = s:search_and_check(kword . ' menu', base_fname, str_info)
+		let lnum = s:append_syn_vimcmd(lnum, str_info, li, 3)
+
+		update
+		quit!
+
+	catch /.*/
+		call s:err_gen('')
+		throw 'exit'
+	endtry
+endfunc
+
+" ------------------------------------------------------------------------------
+function! s:err_gen(arg)
+	call s:write_error(a:arg, 'generator.err')
+endfunc
+
+function! s:err_sanity(arg)
+	call s:write_error(a:arg, 'sanity_check.err')
+endfunc
+
+function! s:write_error(arg, fname)
+	let li = []
+	if !empty(v:throwpoint)
+		call add(li, v:throwpoint)
+	endif
+	if !empty(v:exception)
+		call add(li, v:exception)
+	endif
+	if type(a:arg) == type([])
+		call extend(li, a:arg)
+	elseif type(a:arg) == type("")
+		if !empty(a:arg)
+			call add(li, a:arg)
+		endif
+	endif
+	if !empty(li)
+		call writefile(li, a:fname, 'a')
+	else
+		call writefile(['UNKNOWN'], a:fname, 'a')
+	endif
+endfunc
+
+" ------------------------------------------------------------------------------
+try
+	let s:line_break_len = 768
+	let s:vim_info = {}
+	let s:vim_info.opt = []
+	let s:vim_info.missing_opt = []
+	let s:vim_info.term_out_code = []
+	let s:vim_info.cmd = []
+	let s:vim_info.event = []
+	let s:vim_info.func = []
+	let s:vim_info.hlgroup = []
+
+	set lazyredraw
+	call s:parse_vim_option(s:vim_info.opt, s:vim_info.missing_opt,
+	\						s:vim_info.term_out_code)
+	call s:parse_vim_command(s:vim_info.cmd)
+	call s:parse_vim_event(s:vim_info.event)
+	call s:parse_vim_function(s:vim_info.func)
+	call s:parse_vim_hlgroup(s:vim_info.hlgroup)
+
+	call s:update_syntax_vim_file(s:vim_info)
+	set nolazyredraw
+
+finally
+	quitall!
+endtry
+
+" ---------------------------------------------------------------------
+let &cpo = s:keepcpo
+unlet s:keepcpo
+" vim:ts=4 sw=4
diff --git a/src/gen_syntax_vim/update_date.vim b/src/gen_syntax_vim/update_date.vim
new file mode 100644
--- /dev/null
+++ b/src/gen_syntax_vim/update_date.vim
@@ -0,0 +1,13 @@
+:" Update the date of following line in vim.vim.rc.
+:"     '" Last Change:  '
+:"
+:language C
+:new vim.vim.rc
+:let pat = '^"\s*Last\s*Change:\s\+'
+:let lnum = search(pat, 'We', 10)
+:if lnum > 0
+:   exec 'norm! lD"=strftime("%b %d, %Y")' . "\rp"
+:   update
+:endif
+:quitall!
+:" vim:ts=4 sw=4 et
diff --git a/src/gen_syntax_vim/vim.vim.base b/src/gen_syntax_vim/vim.vim.base
new file mode 100644
--- /dev/null
+++ b/src/gen_syntax_vim/vim.vim.base
@@ -0,0 +1,946 @@
+" Vim syntax file
+" Language:	Vim 7.4 script
+" Maintainer:	Hirohito Higashi <h.east.727 ATMARK gmail.com>
+" Base File Author: Charles E. Campbell <NdrOchipS@PcampbellAfamily.Mbiz>
+" Last Change:	Oct 19, 2015
+" Version:	7.4-36
+
+" DO NOT CHANGE DIRECTLY.
+" THIS FILE PARTLY GENERATED BY gen_syntax_vim.vim.
+" (Search string "GEN_SYN_VIM:" in this file)
+
+" Automatically generated keyword lists: {{{1
+
+" Quit when a syntax file was already loaded {{{2
+if exists("b:current_syntax")
+  finish
+endif
+let s:keepcpo= &cpo
+set cpo&vim
+
+" vimTodo: contains common special-notices for comments {{{2
+" Use the vimCommentGroup cluster to add your own.
+syn keyword vimTodo contained	COMBAK	FIXME	TODO	XXX
+syn cluster vimCommentGroup	contains=vimTodo,@Spell
+
+" regular vim commands {{{2
+" GEN_SYN_VIM: vimCommand normal, START_STR='syn keyword vimCommand contained', END_STR=''
+
+syn match   vimCommand contained	"\<z[-+^.=]\=\>"
+syn keyword vimStdPlugin contained	DiffOrig Man S TOhtml XMLent XMLns
+
+" vimOptions are caught only when contained in a vimSet {{{2
+" GEN_SYN_VIM: vimOption normal, START_STR='syn keyword vimOption contained', END_STR=''
+
+" vimOptions: These are the turn-off setting variants {{{2
+" GEN_SYN_VIM: vimOption turn-off, START_STR='syn keyword vimOption contained', END_STR=''
+
+" vimOptions: These are the invertible variants {{{2
+" GEN_SYN_VIM: vimOption invertible, START_STR='syn keyword vimOption contained', END_STR=''
+
+" termcap codes (which can also be set) {{{2
+" GEN_SYN_VIM: vimOption term output code, START_STR='syn keyword vimOption contained', END_STR=''
+" term key codes
+syn keyword vimOption contained	t_F1 t_F2 t_F3 t_F4 t_F5 t_F6 t_F7 t_F8 t_F9 t_k1 t_K1 t_k2 t_k3 t_K3 t_k4 t_K4 t_k5 t_K5 t_k6 t_K6 t_k7 t_K7 t_k8 t_K8 t_k9 t_K9 t_KA t_kb t_kB t_KB t_KC t_kd t_kD t_KD t_KE t_KF t_KG t_kh t_KH t_kI t_KI t_KJ t_KK t_kl t_KL t_kN t_kP t_kr t_ku
+syn match   vimOption contained	"t_%1"
+syn match   vimOption contained	"t_#2"
+syn match   vimOption contained	"t_#4"
+syn match   vimOption contained	"t_@7"
+syn match   vimOption contained	"t_*7"
+syn match   vimOption contained	"t_&8"
+syn match   vimOption contained	"t_%i"
+syn match   vimOption contained	"t_k;"
+
+" unsupported settings: these are supported by vi but don't do anything in vim {{{2
+" GEN_SYN_VIM: Missing vimOption, START_STR='syn keyword vimErrSetting contained', END_STR=''
+
+" AutoCmd Events {{{2
+syn case ignore
+" GEN_SYN_VIM: vimAutoEvent, START_STR='syn keyword vimAutoEvent contained', END_STR=''
+
+" Highlight commonly used Groupnames {{{2
+syn keyword vimGroup contained	Comment Constant String Character Number Boolean Float Identifier Function Statement Conditional Repeat Label Operator Keyword Exception PreProc Include Define Macro PreCondit Type StorageClass Structure Typedef Special SpecialChar Tag Delimiter SpecialComment Debug Underlined Ignore Error Todo
+
+" Default highlighting groups {{{2
+" GEN_SYN_VIM: vimHLGroup, START_STR='syn keyword vimHLGroup contained', END_STR=''
+syn case match
+
+" Function Names {{{2
+" GEN_SYN_VIM: vimFuncName, START_STR='syn keyword vimFuncName contained', END_STR=''
+
+"--- syntax here and above generated by mkvimvim ---
+" Special Vim Highlighting (not automatic) {{{1
+
+" Set up folding commands
+if exists("g:vimsyn_folding") && g:vimsyn_folding =~ '[aflmpPrt]'
+ if g:vimsyn_folding =~ 'a'
+  com! -nargs=* VimFolda <args> fold
+ else
+  com! -nargs=* VimFolda <args>
+ endif
+ if g:vimsyn_folding =~ 'f'
+  com! -nargs=* VimFoldf <args> fold
+ else
+  com! -nargs=* VimFoldf <args>
+ endif
+ if g:vimsyn_folding =~ 'l'
+  com! -nargs=* VimFoldl <args> fold
+ else
+  com! -nargs=* VimFoldl <args>
+ endif
+ if g:vimsyn_folding =~ 'm'
+  com! -nargs=* VimFoldm <args> fold
+ else
+  com! -nargs=* VimFoldm <args>
+ endif
+ if g:vimsyn_folding =~ 'p'
+  com! -nargs=* VimFoldp <args> fold
+ else
+  com! -nargs=* VimFoldp <args>
+ endif
+ if g:vimsyn_folding =~ 'P'
+  com! -nargs=* VimFoldP <args> fold
+ else
+  com! -nargs=* VimFoldP <args>
+ endif
+ if g:vimsyn_folding =~ 'r'
+  com! -nargs=* VimFoldr <args> fold
+ else
+  com! -nargs=* VimFoldr <args>
+ endif
+ if g:vimsyn_folding =~ 't'
+  com! -nargs=* VimFoldt <args> fold
+ else
+  com! -nargs=* VimFoldt <args>
+ endif
+else
+ com! -nargs=*	VimFolda	<args>
+ com! -nargs=*	VimFoldf	<args>
+ com! -nargs=*	VimFoldl	<args>
+ com! -nargs=*	VimFoldm	<args>
+ com! -nargs=*	VimFoldp	<args>
+ com! -nargs=*	VimFoldP	<args>
+ com! -nargs=*	VimFoldr	<args>
+ com! -nargs=*	VimFoldt	<args>
+endif
+
+" Deprecated variable options {{{2
+if exists("g:vim_minlines")
+ let g:vimsyn_minlines= g:vim_minlines
+endif
+if exists("g:vim_maxlines")
+ let g:vimsyn_maxlines= g:vim_maxlines
+endif
+if exists("g:vimsyntax_noerror")
+ let g:vimsyn_noerror= g:vimsyntax_noerror
+endif
+
+" Numbers {{{2
+" =======
+syn match vimNumber	"\<\d\+\%(\.\d\+\%([eE][+-]\=\d\+\)\=\)\=" skipwhite nextgroup=vimGlobal,vimSubst,vimCommand
+syn match vimNumber	"-\d\+\%(\.\d\+\%([eE][+-]\=\d\+\)\=\)\="  skipwhite nextgroup=vimGlobal,vimSubst,vimCommand
+syn match vimNumber	"\<0[xX]\x\+"
+syn match vimNumber	"\%(^\|[^a-zA-Z]\)\zs#\x\{6}"
+
+" All vimCommands are contained by vimIsCommands. {{{2
+syn match vimCmdSep	"[:|]\+"	skipwhite nextgroup=vimAddress,vimAutoCmd,vimIsCommand,vimExtCmd,vimFilter,vimLet,vimMap,vimMark,vimSet,vimSyntax,vimUserCmd
+syn match vimIsCommand	"\<\h\w*\>"	contains=vimCommand
+syn match vimVar        contained	"\<\h[a-zA-Z0-9#_]*\>"
+syn match vimVar		"\<[bwglsav]:\h[a-zA-Z0-9#_]*\>"
+syn match vimFBVar      contained   "\<[bwglsav]:\h[a-zA-Z0-9#_]*\>"
+syn keyword vimCommand  contained	in
+
+" Insertions And Appends: insert append {{{2
+" =======================
+syn region vimInsert	matchgroup=vimCommand start="^[: \t]*\(\d\+\(,\d\+\)\=\)\=a\%[ppend]$"	matchgroup=vimCommand end="^\.$""
+syn region vimInsert	matchgroup=vimCommand start="^[: \t]*\(\d\+\(,\d\+\)\=\)\=c\%[hange]$"	matchgroup=vimCommand end="^\.$""
+syn region vimInsert	matchgroup=vimCommand start="^[: \t]*\(\d\+\(,\d\+\)\=\)\=i\%[nsert]$"	matchgroup=vimCommand end="^\.$""
+
+" Behave! {{{2
+" =======
+syn match   vimBehave	"\<be\%[have]\>" skipwhite nextgroup=vimBehaveModel,vimBehaveError
+syn keyword vimBehaveModel contained	mswin	xterm
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_nobehaveerror")
+ syn match   vimBehaveError contained	"[^ ]\+"
+endif
+
+" Filetypes {{{2
+" =========
+syn match   vimFiletype	"\<filet\%[ype]\(\s\+\I\i*\)*"	skipwhite contains=vimFTCmd,vimFTOption,vimFTError
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_vimFTError")
+ syn match   vimFTError  contained	"\I\i*"
+endif
+syn keyword vimFTCmd    contained	filet[ype]
+syn keyword vimFTOption contained	detect indent off on plugin
+
+" Augroup : vimAugroupError removed because long augroups caused sync'ing problems. {{{2
+" ======= : Trade-off: Increasing synclines with slower editing vs augroup END error checking.
+syn cluster vimAugroupList	contains=vimAugroup,vimIsCommand,vimCommand,vimUserCmd,vimExecute,vimNotFunc,vimFuncName,vimFunction,vimFunctionError,vimLineComment,vimMap,vimSpecFile,vimOper,vimNumber,vimOperParen,vimComment,vimString,vimSubst,vimMark,vimRegister,vimAddress,vimFilter,vimCmplxRepeat,vimComment,vimLet,vimSet,vimAutoCmd,vimRegion,vimSynLine,vimNotation,vimCtrlChar,vimFuncVar,vimContinue
+if exists("g:vimsyn_folding") && g:vimsyn_folding =~ 'a'
+ syn region  vimAugroup	fold matchgroup=vimAugroupKey start="\<aug\%[roup]\>\ze\s\+\K\k*" end="\<aug\%[roup]\>\ze\s\+[eE][nN][dD]\>"	contains=vimAutoCmd,@vimAugroupList
+else
+ syn region  vimAugroup	matchgroup=vimAugroupKey start="\<aug\%[roup]\>\ze\s\+\K\k*" end="\<aug\%[roup]\>\ze\s\+[eE][nN][dD]\>"	contains=vimAutoCmd,@vimAugroupList
+endif
+syn match   vimAugroup	"aug\%[roup]!"	contains=vimAugroupKey
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_noaugrouperror")
+ syn match   vimAugroupError	"\<aug\%[roup]\>\s\+[eE][nN][dD]\>"
+endif
+syn keyword vimAugroupKey contained	aug[roup]
+
+" Operators: {{{2
+" =========
+syn cluster	vimOperGroup	contains=vimEnvvar,vimFunc,vimFuncVar,vimOper,vimOperParen,vimNumber,vimString,vimRegister,vimContinue
+syn match	vimOper	"\(==\|!=\|>=\|<=\|=\~\|!\~\|>\|<\|=\)[?#]\{0,2}"	skipwhite nextgroup=vimString,vimSpecFile
+syn match	vimOper	"||\|&&\|[-+.]"	skipwhite nextgroup=vimString,vimSpecFile
+syn region	vimOperParen 	matchgroup=vimParenSep	start="(" end=")" contains=@vimOperGroup
+syn region	vimOperParen	matchgroup=vimSep		start="{" end="}" contains=@vimOperGroup nextgroup=vimVar,vimFuncVar
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_noopererror")
+ syn match	vimOperError	")"
+endif
+
+" Functions : Tag is provided for those who wish to highlight tagged functions {{{2
+" =========
+syn cluster	vimFuncList	contains=vimCommand,vimFunctionError,vimFuncKey,Tag,vimFuncSID
+syn cluster	vimFuncBodyList	contains=vimAbb,vimAddress,vimAugroupKey,vimAutoCmd,vimCmplxRepeat,vimComment,vimComment,vimContinue,vimCtrlChar,vimEcho,vimEchoHL,vimExecute,vimIf,vimIsCommand,vimFBVar,vimFunc,vimFunction,vimFuncVar,vimGlobal,vimHighlight,vimIsCommand,vimLet,vimLineComment,vimMap,vimMark,vimNorm,vimNotation,vimNotFunc,vimNumber,vimOper,vimOperParen,vimRegion,vimRegister,vimSet,vimSpecFile,vimString,vimSubst,vimSynLine,vimUnmap,vimUserCommand
+syn match	vimFunction	"\<fu\%[nction]!\=\s\+\%(<[sS][iI][dD]>\|[sSgGbBwWtTlL]:\)\=\%(\i\|[#.]\|{.\{-1,}}\)*\ze\s*("	contains=@vimFuncList nextgroup=vimFuncBody
+
+if exists("g:vimsyn_folding") && g:vimsyn_folding =~ 'f'
+ syn region	vimFuncBody  contained	fold start="\ze\s*("	matchgroup=vimCommand end="\<\(endf\>\|endfu\%[nction]\>\)"		contains=@vimFuncBodyList
+else
+ syn region	vimFuncBody  contained	start="\ze\s*("	matchgroup=vimCommand end="\<\(endf\>\|endfu\%[nction]\>\)"		contains=@vimFuncBodyList
+endif
+syn match	vimFuncVar   contained	"a:\(\K\k*\|\d\+\)"
+syn match	vimFuncSID   contained	"\c<sid>\|\<s:"
+syn keyword	vimFuncKey   contained	fu[nction]
+syn match	vimFuncBlank contained	"\s\+"
+
+syn keyword	vimPattern   contained	start	skip	end
+
+" Special Filenames, Modifiers, Extension Removal: {{{2
+" ===============================================
+syn match	vimSpecFile	"<c\(word\|WORD\)>"	nextgroup=vimSpecFileMod,vimSubst
+syn match	vimSpecFile	"<\([acs]file\|amatch\|abuf\)>"	nextgroup=vimSpecFileMod,vimSubst
+syn match	vimSpecFile	"\s%[ \t:]"ms=s+1,me=e-1	nextgroup=vimSpecFileMod,vimSubst
+syn match	vimSpecFile	"\s%$"ms=s+1	nextgroup=vimSpecFileMod,vimSubst
+syn match	vimSpecFile	"\s%<"ms=s+1,me=e-1	nextgroup=vimSpecFileMod,vimSubst
+syn match	vimSpecFile	"#\d\+\|[#%]<\>"	nextgroup=vimSpecFileMod,vimSubst
+syn match	vimSpecFileMod	"\(:[phtre]\)\+"	contained
+
+" User-Specified Commands: {{{2
+" =======================
+syn cluster	vimUserCmdList	contains=vimAddress,vimSyntax,vimHighlight,vimAutoCmd,vimCmplxRepeat,vimComment,vimCtrlChar,vimEscapeBrace,vimFilter,vimFunc,vimFuncName,vimFunction,vimFunctionError,vimIsCommand,vimMark,vimNotation,vimNumber,vimOper,vimRegion,vimRegister,vimLet,vimSet,vimSetEqual,vimSetString,vimSpecFile,vimString,vimSubst,vimSubstRep,vimSubstRange,vimSynLine
+syn keyword	vimUserCommand	contained	com[mand]
+syn match	vimUserCmd	"\<com\%[mand]!\=\>.*$"	contains=vimUserAttrb,vimUserAttrbError,vimUserCommand,@vimUserCmdList
+syn match	vimUserAttrbError	contained	"-\a\+\ze\s"
+syn match	vimUserAttrb	contained	"-nargs=[01*?+]"	contains=vimUserAttrbKey,vimOper
+syn match	vimUserAttrb	contained	"-complete="		contains=vimUserAttrbKey,vimOper nextgroup=vimUserAttrbCmplt,vimUserCmdError
+syn match	vimUserAttrb	contained	"-range\(=%\|=\d\+\)\="	contains=vimNumber,vimOper,vimUserAttrbKey
+syn match	vimUserAttrb	contained	"-count\(=\d\+\)\="	contains=vimNumber,vimOper,vimUserAttrbKey
+syn match	vimUserAttrb	contained	"-bang\>"		contains=vimOper,vimUserAttrbKey
+syn match	vimUserAttrb	contained	"-bar\>"		contains=vimOper,vimUserAttrbKey
+syn match	vimUserAttrb	contained	"-buffer\>"		contains=vimOper,vimUserAttrbKey
+syn match	vimUserAttrb	contained	"-register\>"		contains=vimOper,vimUserAttrbKey
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_nousercmderror")
+ syn match	vimUserCmdError	contained	"\S\+\>"
+endif
+syn case ignore
+syn keyword	vimUserAttrbKey   contained	bar	ban[g]	cou[nt]	ra[nge] com[plete]	n[args]	re[gister]
+syn keyword	vimUserAttrbCmplt contained	augroup buffer color command compiler cscope dir environment event expression file file_in_path filetype function help highlight locale mapping menu option shellcmd sign syntax tag tag_listfiles var
+syn keyword	vimUserAttrbCmplt contained	custom customlist nextgroup=vimUserAttrbCmpltFunc,vimUserCmdError
+syn match	vimUserAttrbCmpltFunc contained	",\%([sS]:\|<[sS][iI][dD]>\)\=\%(\h\w*\%(#\h\w*\)\+\|\h\w*\)"hs=s+1 nextgroup=vimUserCmdError
+
+syn case match
+syn match	vimUserAttrbCmplt contained	"custom,\u\w*"
+
+" Lower Priority Comments: after some vim commands... {{{2
+" =======================
+syn match	vimComment	excludenl +\s"[^\-:.%#=*].*$+lc=1	contains=@vimCommentGroup,vimCommentString
+syn match	vimComment	+\<endif\s\+".*$+lc=5	contains=@vimCommentGroup,vimCommentString
+syn match	vimComment	+\<else\s\+".*$+lc=4	contains=@vimCommentGroup,vimCommentString
+syn region	vimCommentString	contained oneline start='\S\s\+"'ms=e	end='"'
+
+" Environment Variables: {{{2
+" =====================
+syn match	vimEnvvar	"\$\I\i*"
+syn match	vimEnvvar	"\${\I\i*}"
+
+" In-String Specials: {{{2
+" Try to catch strings, if nothing else matches (therefore it must precede the others!)
+"  vimEscapeBrace handles ["]  []"] (ie. "s don't terminate string inside [])
+syn region	vimEscapeBrace	oneline   contained transparent start="[^\\]\(\\\\\)*\[\zs\^\=\]\=" skip="\\\\\|\\\]" end="]"me=e-1
+syn match	vimPatSepErr	contained	"\\)"
+syn match	vimPatSep	contained	"\\|"
+syn region	vimPatSepZone	oneline   contained   matchgroup=vimPatSepZ start="\\%\=\ze(" skip="\\\\" end="\\)\|[^\]['"]"	contains=@vimStringGroup
+syn region	vimPatRegion	contained transparent matchgroup=vimPatSepR start="\\[z%]\=(" end="\\)"	contains=@vimSubstList oneline
+syn match	vimNotPatSep	contained	"\\\\"
+syn cluster	vimStringGroup	contains=vimEscapeBrace,vimPatSep,vimNotPatSep,vimPatSepErr,vimPatSepZone,@Spell
+syn region	vimString	oneline keepend	start=+[^:a-zA-Z>!\\@]"+lc=1 skip=+\\\\\|\\"+ end=+"+	contains=@vimStringGroup
+syn region	vimString	oneline keepend	start=+[^:a-zA-Z>!\\@]'+lc=1 end=+'+
+syn region	vimString	oneline	start=+=!+lc=1	skip=+\\\\\|\\!+ end=+!+	contains=@vimStringGroup
+syn region	vimString	oneline	start="=+"lc=1	skip="\\\\\|\\+" end="+"	contains=@vimStringGroup
+syn region	vimString	oneline	start="\s/\s*\A"lc=1 skip="\\\\\|\\+" end="/"	contains=@vimStringGroup
+syn match	vimString	contained	+"[^"]*\\$+	skipnl nextgroup=vimStringCont
+syn match	vimStringCont	contained	+\(\\\\\|.\)\{-}[^\\]"+
+
+" Substitutions: {{{2
+" =============
+syn cluster	vimSubstList	contains=vimPatSep,vimPatRegion,vimPatSepErr,vimSubstTwoBS,vimSubstRange,vimNotation
+syn cluster	vimSubstRepList	contains=vimSubstSubstr,vimSubstTwoBS,vimNotation
+syn cluster	vimSubstList	add=vimCollection
+syn match	vimSubst	"\(:\+\s*\|^\s*\||\s*\)\<\%(s\%[ubstitute]\|sm\%[agic]\|sno\%[magic]\)[:[:alpha:]]\@!" nextgroup=vimSubstPat
+syn match	vimSubst	"s\%[ubstitute][:#[:alpha:]]\@!"	nextgroup=vimSubstPat contained
+syn match	vimSubst	"/\zss\%[ubstitute]\ze/"	nextgroup=vimSubstPat
+syn match	vimSubst1       contained	"s\%[ubstitute]\>"	nextgroup=vimSubstPat
+syn region	vimSubstPat     contained	matchgroup=vimSubstDelim start="\z([^a-zA-Z( \t[\]&]\)"rs=s+1 skip="\\\\\|\\\z1" end="\z1"re=e-1,me=e-1	 contains=@vimSubstList	nextgroup=vimSubstRep4	oneline
+syn region	vimSubstRep4    contained	matchgroup=vimSubstDelim start="\z(.\)" skip="\\\\\|\\\z1" end="\z1" matchgroup=vimNotation end="<[cC][rR]>" contains=@vimSubstRepList	nextgroup=vimSubstFlagErr	oneline
+syn region	vimCollection   contained transparent	start="\\\@<!\[" skip="\\\[" end="\]"	contains=vimCollClass
+syn match	vimCollClassErr contained	"\[:.\{-\}:\]"
+syn match	vimCollClass    contained transparent	"\[:\(alnum\|alpha\|blank\|cntrl\|digit\|graph\|lower\|print\|punct\|space\|upper\|xdigit\|return\|tab\|escape\|backspace\):\]"
+syn match	vimSubstSubstr  contained	"\\z\=\d"
+syn match	vimSubstTwoBS   contained	"\\\\"
+syn match	vimSubstFlagErr contained	"[^< \t\r|]\+" contains=vimSubstFlags
+syn match	vimSubstFlags   contained	"[&cegiIpr]\+"
+
+" 'String': {{{2
+syn match	vimString	"[^(,]'[^']\{-}\zs'"
+
+" Marks, Registers, Addresses, Filters: {{{2
+syn match	vimMark	"'[a-zA-Z0-9]\ze[-+,!]"	nextgroup=vimOper,vimMarkNumber,vimSubst
+syn match	vimMark	"'[<>]\ze[-+,!]"		nextgroup=vimOper,vimMarkNumber,vimSubst
+syn match	vimMark	",\zs'[<>]\ze"		nextgroup=vimOper,vimMarkNumber,vimSubst
+syn match	vimMark	"[!,:]\zs'[a-zA-Z0-9]"	nextgroup=vimOper,vimMarkNumber,vimSubst
+syn match	vimMark	"\<norm\%[al]\s\zs'[a-zA-Z0-9]"	nextgroup=vimOper,vimMarkNumber,vimSubst
+syn match	vimMarkNumber	"[-+]\d\+"		nextgroup=vimSubst contained contains=vimOper
+syn match	vimPlainMark contained	"'[a-zA-Z0-9]"
+
+syn match	vimRegister	'[^,;[{: \t]\zs"[a-zA-Z0-9.%#:_\-/]\ze[^a-zA-Z_":0-9]'
+syn match	vimRegister	'\<norm\s\+\zs"[a-zA-Z0-9]'
+syn match	vimRegister	'\<normal\s\+\zs"[a-zA-Z0-9]'
+syn match	vimRegister	'@"'
+syn match	vimPlainRegister contained	'"[a-zA-Z0-9\-:.%#*+=]'
+
+syn match	vimAddress	",\zs[.$]"	skipwhite nextgroup=vimSubst1
+syn match	vimAddress	"%\ze\a"	skipwhite nextgroup=vimString,vimSubst1
+
+syn match	vimFilter contained	"^!.\{-}\(|\|$\)"		contains=vimSpecFile
+syn match	vimFilter contained	"\A!.\{-}\(|\|$\)"ms=s+1	contains=vimSpecFile,vimFunction,vimFuncName,vimOperParen
+
+" Complex repeats (:h complex-repeat) {{{2
+syn match	vimCmplxRepeat	'[^a-zA-Z_/\\()]q[0-9a-zA-Z"]\>'lc=1
+syn match	vimCmplxRepeat	'@[0-9a-z".=@:]\ze\($\|[^a-zA-Z]\>\)'
+
+" Set command and associated set-options (vimOptions) with comment {{{2
+syn region	vimSet		matchgroup=vimCommand start="\<\%(setl\%[ocal]\|setg\%[lobal]\|se\%[t]\)\>" skip="\%(\\\\\)*\\." end="$" matchgroup=vimNotation end="<[cC][rR]>" keepend oneline contains=vimSetEqual,vimOption,vimErrSetting,vimComment,vimSetString,vimSetMod
+syn region	vimSetEqual	contained	start="[=:]\|[-+^]=" skip="\\\\\|\\\s" end="[| \t]\|$"me=e-1 contains=vimCtrlChar,vimSetSep,vimNotation,vimEnvvar oneline
+syn region	vimSetString	contained	start=+="+hs=s+1	skip=+\\\\\|\\"+  end=+"+	contains=vimCtrlChar
+syn match	vimSetSep	contained	"[,:]" skipwhite nextgroup=vimCommand
+syn match	vimSetMod	contained	"&vim\=\|[!&?<]\|all&"
+
+" Let {{{2
+" ===
+syn keyword	vimLet	let	unl[et]	skipwhite nextgroup=vimVar,vimFuncVar
+
+" Abbreviations {{{2
+" =============
+" GEN_SYN_VIM: vimCommand abbrev, START_STR='syn keyword vimAbb', END_STR='skipwhite nextgroup=vimMapMod,vimMapLhs'
+
+" Autocmd {{{2
+" =======
+syn match	vimAutoEventList	contained	"\(!\s\+\)\=\(\a\+,\)*\a\+"	contains=vimAutoEvent nextgroup=vimAutoCmdSpace
+syn match	vimAutoCmdSpace	contained	"\s\+"	nextgroup=vimAutoCmdSfxList
+syn match	vimAutoCmdSfxList	contained	"\S*"
+syn keyword	vimAutoCmd	au[tocmd] do[autocmd] doautoa[ll]	skipwhite nextgroup=vimAutoEventList
+
+" Echo and Execute -- prefer strings! {{{2
+" ================
+syn region	vimEcho	oneline excludenl matchgroup=vimCommand start="\<ec\%[ho]\>" skip="\(\\\\\)*\\|" end="$\||" contains=vimFunc,vimFuncVar,vimString,vimVar
+syn region	vimExecute	oneline excludenl matchgroup=vimCommand start="\<exe\%[cute]\>" skip="\(\\\\\)*\\|" end="$\||\|<[cC][rR]>" contains=vimFuncVar,vimIsCommand,vimOper,vimNotation,vimOperParen,vimString,vimVar
+syn match	vimEchoHL	"echohl\="	skipwhite nextgroup=vimGroup,vimHLGroup,vimEchoHLNone
+syn case ignore
+syn keyword	vimEchoHLNone	none
+syn case match
+
+" Maps {{{2
+" ====
+syn match	vimMap		"\<map\>!\=\ze\s*[^(]" skipwhite nextgroup=vimMapMod,vimMapLhs
+" GEN_SYN_VIM: vimCommand map, START_STR='syn keyword vimMap', END_STR='skipwhite nextgroup=vimMapBang,vimMapMod,vimMapLhs'
+" GEN_SYN_VIM: vimCommand mapclear, START_STR='syn keyword vimMap', END_STR=''
+" GEN_SYN_VIM: vimCommand unmap, START_STR='syn keyword vimMap', END_STR='skipwhite nextgroup=vimMapBang,vimMapMod,vimMapLhs'
+syn match	vimMapLhs	contained	"\S\+"			contains=vimNotation,vimCtrlChar skipwhite nextgroup=vimMapRhs
+syn match	vimMapBang	contained	"!"			skipwhite nextgroup=vimMapMod,vimMapLhs
+syn match	vimMapMod	contained	"\c<\(buffer\|expr\|\(local\)\=leader\|nowait\|plug\|script\|sid\|unique\|silent\)\+>" contains=vimMapModKey,vimMapModErr skipwhite nextgroup=vimMapMod,vimMapLhs
+syn match	vimMapRhs	contained	".*" contains=vimNotation,vimCtrlChar	skipnl nextgroup=vimMapRhsExtend
+syn match	vimMapRhsExtend	contained	"^\s*\\.*$"			contains=vimContinue
+syn case ignore
+syn keyword	vimMapModKey	contained	buffer	expr	leader	localleader	nowait	plug	script	sid	silent	unique
+syn case match
+
+" Menus {{{2
+" =====
+syn cluster	vimMenuList contains=vimMenuBang,vimMenuPriority,vimMenuName,vimMenuMod
+" GEN_SYN_VIM: vimCommand menu, START_STR='syn keyword vimCommand', END_STR='skipwhite nextgroup=@vimMenuList'
+syn match	vimMenuName	"[^ \t\\<]\+"	contained nextgroup=vimMenuNameMore,vimMenuMap
+syn match	vimMenuPriority	"\d\+\(\.\d\+\)*"	contained skipwhite nextgroup=vimMenuName
+syn match	vimMenuNameMore	"\c\\\s\|<tab>\|\\\."	contained nextgroup=vimMenuName,vimMenuNameMore contains=vimNotation
+syn match	vimMenuMod    contained	"\c<\(script\|silent\)\+>"  skipwhite contains=vimMapModKey,vimMapModErr nextgroup=@vimMenuList
+syn match	vimMenuMap	"\s"	contained skipwhite nextgroup=vimMenuRhs
+syn match	vimMenuRhs	".*$"	contained contains=vimString,vimComment,vimIsCommand
+syn match	vimMenuBang	"!"	contained skipwhite nextgroup=@vimMenuList
+
+" Angle-Bracket Notation (tnx to Michael Geddes) {{{2
+" ======================
+syn case ignore
+syn match	vimNotation	"\(\\\|<lt>\)\=<\([scamd]-\)\{0,4}x\=\(f\d\{1,2}\|[^ \t:]\|cr\|lf\|linefeed\|return\|k\=del\%[ete]\|bs\|backspace\|tab\|esc\|right\|left\|help\|undo\|insert\|ins\|k\=home\|k\=end\|kplus\|kminus\|kdivide\|kmultiply\|kenter\|kpoint\|space\|k\=\(page\)\=\(\|down\|up\|k\d\>\)\)>" contains=vimBracket
+syn match	vimNotation	"\(\\\|<lt>\)\=<\([scam2-4]-\)\{0,4}\(right\|left\|middle\)\(mouse\)\=\(drag\|release\)\=>"	contains=vimBracket
+syn match	vimNotation	"\(\\\|<lt>\)\=<\(bslash\|plug\|sid\|space\|bar\|nop\|nul\|lt\)>"		contains=vimBracket
+syn match	vimNotation	'\(\\\|<lt>\)\=<C-R>[0-9a-z"%#:.\-=]'he=e-1			contains=vimBracket
+syn match	vimNotation	'\(\\\|<lt>\)\=<\%(q-\)\=\(line[12]\|count\|bang\|reg\|args\|f-args\|lt\)>'	contains=vimBracket
+syn match	vimNotation	"\(\\\|<lt>\)\=<\([cas]file\|abuf\|amatch\|cword\|cWORD\|client\)>"		contains=vimBracket
+syn match	vimBracket contained	"[\\<>]"
+syn case match
+
+" User Function Highlighting {{{2
+" (following Gautam Iyer's suggestion)
+" ==========================
+syn match vimFunc		"\%(\%([sSgGbBwWtTlL]:\|<[sS][iI][dD]>\)\=\%([a-zA-Z0-9_]\+\.\)*\I[a-zA-Z0-9_.]*\)\ze\s*("		contains=vimFuncName,vimUserFunc,vimExecute
+syn match vimUserFunc contained	"\%(\%([sSgGbBwWtTlL]:\|<[sS][iI][dD]>\)\=\%([a-zA-Z0-9_]\+\.\)*\I[a-zA-Z0-9_.]*\)\|\<\u[a-zA-Z0-9.]*\>\|\<if\>"	contains=vimNotation
+syn match vimNotFunc	"\<if\>\|\<el\%[seif]\>\|\<return\>\|\<while\>"
+
+" Errors And Warnings: {{{2
+" ====================
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_novimfunctionerror")
+ syn match	vimFunctionError	"\s\zs[a-z0-9]\i\{-}\ze\s*("			contained contains=vimFuncKey,vimFuncBlank
+" syn match	vimFunctionError	"\s\zs\%(<[sS][iI][dD]>\|[sSgGbBwWtTlL]:\)[0-9]\i\{-}\ze\s*("	contained contains=vimFuncKey,vimFuncBlank
+ syn match	vimElseIfErr	"\<else\s\+if\>"
+ syn match	vimBufnrWarn	/\<bufnr\s*(\s*["']\.['"]\s*)/
+endif
+
+" Norm {{{2
+" ====
+syn match	vimNorm		"\<norm\%[al]!\=" skipwhite nextgroup=vimNormCmds
+syn match	vimNormCmds contained	".*$"
+
+" Syntax {{{2
+"=======
+syn match	vimGroupList	contained	"@\=[^ \t,]*"	contains=vimGroupSpecial,vimPatSep
+syn match	vimGroupList	contained	"@\=[^ \t,]*,"	nextgroup=vimGroupList contains=vimGroupSpecial,vimPatSep
+syn keyword	vimGroupSpecial	contained	ALL	ALLBUT	CONTAINED	TOP
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_novimsynerror")
+ syn match	vimSynError	contained	"\i\+"
+ syn match	vimSynError	contained	"\i\+="	nextgroup=vimGroupList
+endif
+syn match	vimSynContains	contained	"\<contain\(s\|edin\)="	nextgroup=vimGroupList
+syn match	vimSynKeyContainedin	contained	"\<containedin="	nextgroup=vimGroupList
+syn match	vimSynNextgroup	contained	"nextgroup="	nextgroup=vimGroupList
+
+syn match	vimSyntax	"\<sy\%[ntax]\>"	contains=vimCommand skipwhite nextgroup=vimSynType,vimComment
+syn match	vimAuSyntax	contained	"\s+sy\%[ntax]"	contains=vimCommand skipwhite nextgroup=vimSynType,vimComment
+syn cluster vimFuncBodyList add=vimSyntax
+
+" Syntax: case {{{2
+syn keyword	vimSynType	contained	case	skipwhite nextgroup=vimSynCase,vimSynCaseError
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_novimsyncaseerror")
+ syn match	vimSynCaseError	contained	"\i\+"
+endif
+syn keyword	vimSynCase	contained	ignore	match
+
+" Syntax: clear {{{2
+syn keyword	vimSynType	contained	clear	skipwhite nextgroup=vimGroupList
+
+" Syntax: cluster {{{2
+syn keyword	vimSynType	contained	cluster	skipwhite nextgroup=vimClusterName
+syn region	vimClusterName	contained	matchgroup=vimGroupName start="\h\w*" skip="\\\\\|\\|" matchgroup=vimSep end="$\||" contains=vimGroupAdd,vimGroupRem,vimSynContains,vimSynError
+syn match	vimGroupAdd	contained	"add="	nextgroup=vimGroupList
+syn match	vimGroupRem	contained	"remove="	nextgroup=vimGroupList
+syn cluster vimFuncBodyList add=vimSynType,vimGroupAdd,vimGroupRem
+
+" Syntax: include {{{2
+syn keyword	vimSynType	contained	include	skipwhite nextgroup=vimGroupList
+syn cluster vimFuncBodyList add=vimSynType
+
+" Syntax: keyword {{{2
+syn cluster	vimSynKeyGroup	contains=vimSynNextgroup,vimSynKeyOpt,vimSynKeyContainedin
+syn keyword	vimSynType	contained	keyword	skipwhite nextgroup=vimSynKeyRegion
+syn region	vimSynKeyRegion	contained oneline keepend	matchgroup=vimGroupName start="\h\w*" skip="\\\\\|\\|" matchgroup=vimSep end="|\|$" contains=@vimSynKeyGroup
+syn match	vimSynKeyOpt	contained	"\<\(conceal\|contained\|transparent\|skipempty\|skipwhite\|skipnl\)\>"
+syn cluster vimFuncBodyList add=vimSynType
+
+" Syntax: match {{{2
+syn cluster	vimSynMtchGroup	contains=vimMtchComment,vimSynContains,vimSynError,vimSynMtchOpt,vimSynNextgroup,vimSynRegPat,vimNotation
+syn keyword	vimSynType	contained	match	skipwhite nextgroup=vimSynMatchRegion
+syn region	vimSynMatchRegion	contained keepend	matchgroup=vimGroupName start="\h\w*" matchgroup=vimSep end="|\|$" contains=@vimSynMtchGroup
+syn match	vimSynMtchOpt	contained	"\<\(conceal\|transparent\|contained\|excludenl\|skipempty\|skipwhite\|display\|extend\|skipnl\|fold\)\>"
+if has("conceal")
+ syn match	vimSynMtchOpt	contained	"\<cchar="	nextgroup=vimSynMtchCchar
+ syn match	vimSynMtchCchar	contained	"\S"
+endif
+syn cluster vimFuncBodyList add=vimSynMtchGroup
+
+" Syntax: off and on {{{2
+syn keyword	vimSynType	contained	enable	list	manual	off	on	reset
+
+" Syntax: region {{{2
+syn cluster	vimSynRegPatGroup	contains=vimPatSep,vimNotPatSep,vimSynPatRange,vimSynNotPatRange,vimSubstSubstr,vimPatRegion,vimPatSepErr,vimNotation
+syn cluster	vimSynRegGroup	contains=vimSynContains,vimSynNextgroup,vimSynRegOpt,vimSynReg,vimSynMtchGrp
+syn keyword	vimSynType	contained	region	skipwhite nextgroup=vimSynRegion
+syn region	vimSynRegion	contained keepend	matchgroup=vimGroupName start="\h\w*" skip="\\\\\|\\|" end="|\|$" contains=@vimSynRegGroup
+syn match	vimSynRegOpt	contained	"\<\(conceal\(ends\)\=\|transparent\|contained\|excludenl\|skipempty\|skipwhite\|display\|keepend\|oneline\|extend\|skipnl\|fold\)\>"
+syn match	vimSynReg	contained	"\(start\|skip\|end\)="he=e-1	nextgroup=vimSynRegPat
+syn match	vimSynMtchGrp	contained	"matchgroup="	nextgroup=vimGroup,vimHLGroup
+syn region	vimSynRegPat	contained extend	start="\z([-`~!@#$%^&*_=+;:'",./?]\)"  skip="\\\\\|\\\z1"  end="\z1"  contains=@vimSynRegPatGroup skipwhite nextgroup=vimSynPatMod,vimSynReg
+syn match	vimSynPatMod	contained	"\(hs\|ms\|me\|hs\|he\|rs\|re\)=[se]\([-+]\d\+\)\="
+syn match	vimSynPatMod	contained	"\(hs\|ms\|me\|hs\|he\|rs\|re\)=[se]\([-+]\d\+\)\=," nextgroup=vimSynPatMod
+syn match	vimSynPatMod	contained	"lc=\d\+"
+syn match	vimSynPatMod	contained	"lc=\d\+," nextgroup=vimSynPatMod
+syn region	vimSynPatRange	contained	start="\["	skip="\\\\\|\\]"   end="]"
+syn match	vimSynNotPatRange	contained	"\\\\\|\\\["
+syn match	vimMtchComment	contained	'"[^"]\+$'
+syn cluster vimFuncBodyList add=vimSynType
+
+" Syntax: sync {{{2
+" ============
+syn keyword vimSynType	contained	sync	skipwhite	nextgroup=vimSyncC,vimSyncLines,vimSyncMatch,vimSyncError,vimSyncLinebreak,vimSyncLinecont,vimSyncRegion
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_novimsyncerror")
+ syn match	vimSyncError	contained	"\i\+"
+endif
+syn keyword	vimSyncC	contained	ccomment	clear	fromstart
+syn keyword	vimSyncMatch	contained	match	skipwhite	nextgroup=vimSyncGroupName
+syn keyword	vimSyncRegion	contained	region	skipwhite	nextgroup=vimSynReg
+syn match	vimSyncLinebreak	contained	"\<linebreaks="	skipwhite	nextgroup=vimNumber
+syn keyword	vimSyncLinecont	contained	linecont	skipwhite	nextgroup=vimSynRegPat
+syn match	vimSyncLines	contained	"\(min\|max\)\=lines="	nextgroup=vimNumber
+syn match	vimSyncGroupName	contained	"\h\w*"	skipwhite	nextgroup=vimSyncKey
+syn match	vimSyncKey	contained	"\<groupthere\|grouphere\>"	skipwhite nextgroup=vimSyncGroup
+syn match	vimSyncGroup	contained	"\h\w*"	skipwhite	nextgroup=vimSynRegPat,vimSyncNone
+syn keyword	vimSyncNone	contained	NONE
+
+" Additional IsCommand, here by reasons of precedence {{{2
+" ====================
+syn match	vimIsCommand	"<Bar>\s*\a\+"	transparent contains=vimCommand,vimNotation
+
+" Highlighting {{{2
+" ============
+syn cluster	vimHighlightCluster		contains=vimHiLink,vimHiClear,vimHiKeyList,vimComment
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_novimhictermerror")
+ syn match	vimHiCtermError	contained	"[^0-9]\i*"
+endif
+syn match	vimHighlight	"\<hi\%[ghlight]\>"	skipwhite nextgroup=vimHiBang,@vimHighlightCluster
+syn match	vimHiBang	contained	"!"	skipwhite nextgroup=@vimHighlightCluster
+
+syn match	vimHiGroup	contained	"\i\+"
+syn case ignore
+syn keyword	vimHiAttrib	contained	none bold inverse italic reverse standout underline undercurl
+syn keyword	vimFgBgAttrib	contained	none bg background fg foreground
+syn case match
+syn match	vimHiAttribList	contained	"\i\+"	contains=vimHiAttrib
+syn match	vimHiAttribList	contained	"\i\+,"he=e-1	contains=vimHiAttrib nextgroup=vimHiAttribList
+syn case ignore
+syn keyword	vimHiCtermColor	contained	black blue brown cyan darkblue darkcyan darkgray darkgreen darkgrey darkmagenta darkred darkyellow gray green grey lightblue lightcyan lightgray lightgreen lightgrey lightmagenta lightred magenta red white yellow
+syn match	vimHiCtermColor	contained	"\<color\d\{1,3}\>"
+
+syn case match
+syn match	vimHiFontname	contained	"[a-zA-Z\-*]\+"
+syn match	vimHiGuiFontname	contained	"'[a-zA-Z\-* ]\+'"
+syn match	vimHiGuiRgb	contained	"#\x\{6}"
+
+" Highlighting: hi group key=arg ... {{{2
+syn cluster	vimHiCluster contains=vimGroup,vimHiGroup,vimHiTerm,vimHiCTerm,vimHiStartStop,vimHiCtermFgBg,vimHiGui,vimHiGuiFont,vimHiGuiFgBg,vimHiKeyError,vimNotation
+syn region	vimHiKeyList	contained oneline start="\i\+" skip="\\\\\|\\|" end="$\||"	contains=@vimHiCluster
+if !exists("g:vimsyn_noerror") && !exists("g:vimsyn_vimhikeyerror")
+ syn match	vimHiKeyError	contained	"\i\+="he=e-1
+endif
+syn match	vimHiTerm	contained	"\cterm="he=e-1		nextgroup=vimHiAttribList
+syn match	vimHiStartStop	contained	"\c\(start\|stop\)="he=e-1	nextgroup=vimHiTermcap,vimOption
+syn match	vimHiCTerm	contained	"\ccterm="he=e-1		nextgroup=vimHiAttribList
+syn match	vimHiCtermFgBg	contained	"\ccterm[fb]g="he=e-1	nextgroup=vimHiNmbr,vimHiCtermColor,vimFgBgAttrib,vimHiCtermError
+syn match	vimHiGui	contained	"\cgui="he=e-1		nextgroup=vimHiAttribList
+syn match	vimHiGuiFont	contained	"\cfont="he=e-1		nextgroup=vimHiFontname
+syn match	vimHiGuiFgBg	contained	"\cgui\%([fb]g\|sp\)="he=e-1	nextgroup=vimHiGroup,vimHiGuiFontname,vimHiGuiRgb,vimFgBgAttrib
+syn match	vimHiTermcap	contained	"\S\+"		contains=vimNotation
+syn match	vimHiNmbr	contained	'\d\+'
+
+" Highlight: clear {{{2
+syn keyword	vimHiClear	contained	clear	nextgroup=vimHiGroup
+
+" Highlight: link {{{2
+syn region	vimHiLink	contained oneline matchgroup=vimCommand start="\(\<hi\%[ghlight]\s\+\)\@<=\(\(def\%[ault]\s\+\)\=link\>\|\<def\>\)" end="$"	contains=vimHiGroup,vimGroup,vimHLGroup,vimNotation
+syn cluster vimFuncBodyList add=vimHiLink
+
+" Control Characters {{{2
+" ==================
+syn match	vimCtrlChar	"[--]"
+
+" Beginners - Patterns that involve ^ {{{2
+" =========
+syn match	vimLineComment	+^[ \t:]*".*$+	contains=@vimCommentGroup,vimCommentString,vimCommentTitle
+syn match	vimCommentTitle	'"\s*\%([sS]:\|\h\w*#\)\=\u\w*\(\s\+\u\w*\)*:'hs=s+1	contained contains=vimCommentTitleLeader,vimTodo,@vimCommentGroup
+syn match	vimContinue	"^\s*\\"
+syn region	vimString	start="^\s*\\\z(['"]\)" skip='\\\\\|\\\z1' end="\z1" oneline keepend contains=@vimStringGroup,vimContinue
+syn match	vimCommentTitleLeader	'"\s\+'ms=s+1	contained
+
+" Searches And Globals: {{{2
+" ====================
+syn match	vimSearch	'^\s*[/?].*'		contains=vimSearchDelim
+syn match	vimSearchDelim	'^\s*\zs[/?]\|[/?]$'	contained
+syn region	vimGlobal	matchgroup=Statement start='\<g\%[lobal]!\=/'  skip='\\.' end='/'	skipwhite nextgroup=vimSubst
+syn region	vimGlobal	matchgroup=Statement start='\<v\%[global]!\=/' skip='\\.' end='/'	skipwhite nextgroup=vimSubst
+
+" Scripts  : perl,ruby : Benoit Cerrina {{{2
+" =======    python,tcl: Johannes Zellner
+"            lua
+
+" Allows users to specify the type of embedded script highlighting
+" they want:  (perl/python/ruby/tcl support)
+"   g:vimsyn_embed == 0   : don't embed any scripts
+"   g:vimsyn_embed =~ 'l' : embed lua      (but only if vim supports it)
+"   g:vimsyn_embed =~ 'm' : embed mzscheme (but only if vim supports it)
+"   g:vimsyn_embed =~ 'p' : embed perl     (but only if vim supports it)
+"   g:vimsyn_embed =~ 'P' : embed python   (but only if vim supports it)
+"   g:vimsyn_embed =~ 'r' : embed ruby     (but only if vim supports it)
+"   g:vimsyn_embed =~ 't' : embed tcl      (but only if vim supports it)
+if !exists("g:vimsyn_embed")
+ let g:vimsyn_embed= "lmpPr"
+endif
+
+" [-- lua --] {{{3
+let s:luapath= fnameescape(expand("<sfile>:p:h")."/lua.vim")
+if !filereadable(s:luapath)
+ for s:luapath in split(globpath(&rtp,"syntax/lua.vim"),"\n")
+  if filereadable(fnameescape(s:luapath))
+   let s:luapath= fnameescape(s:luapath)
+   break
+  endif
+ endfor
+endif
+if (g:vimsyn_embed =~ 'l' && has("lua")) && filereadable(s:luapath)
+ unlet! b:current_syntax
+ exe "syn include @vimLuaScript ".s:luapath
+ VimFoldl syn region vimLuaRegion matchgroup=vimScriptDelim start=+lua\s*<<\s*\z(.*\)$+ end=+^\z1$+	contains=@vimLuaScript
+ VimFoldl syn region vimLuaRegion matchgroup=vimScriptDelim start=+lua\s*<<\s*$+ end=+\.$+		contains=@vimLuaScript
+ syn cluster vimFuncBodyList	add=vimLuaRegion
+else
+ syn region vimEmbedError start=+lua\s*<<\s*\z(.*\)$+ end=+^\z1$+
+ syn region vimEmbedError start=+lua\s*<<\s*$+ end=+\.$+
+endif
+unlet s:luapath
+
+" [-- perl --] {{{3
+let s:perlpath= fnameescape(expand("<sfile>:p:h")."/perl.vim")
+if !filereadable(s:perlpath)
+ for s:perlpath in split(globpath(&rtp,"syntax/perl.vim"),"\n")
+  if filereadable(fnameescape(s:perlpath))
+   let s:perlpath= fnameescape(s:perlpath)
+   break
+  endif
+ endfor
+endif
+if (g:vimsyn_embed =~ 'p' && has("perl")) && filereadable(s:perlpath)
+ unlet! b:current_syntax
+ exe "syn include @vimPerlScript ".s:perlpath
+ VimFoldp syn region vimPerlRegion  matchgroup=vimScriptDelim start=+pe\%[rl]\s*<<\s*\z(.*\)$+ end=+^\z1$+	contains=@vimPerlScript
+ VimFoldp syn region vimPerlRegion	matchgroup=vimScriptDelim start=+pe\%[rl]\s*<<\s*$+ end=+\.$+	contains=@vimPerlScript
+ syn cluster vimFuncBodyList	add=vimPerlRegion
+else
+ syn region vimEmbedError start=+pe\%[rl]\s*<<\s*\z(.*\)$+ end=+^\z1$+
+ syn region vimEmbedError start=+pe\%[rl]\s*<<\s*$+ end=+\.$+
+endif
+unlet s:perlpath
+
+" [-- ruby --] {{{3
+let s:rubypath= fnameescape(expand("<sfile>:p:h")."/ruby.vim")
+if !filereadable(s:rubypath)
+ for s:rubypath in split(globpath(&rtp,"syntax/ruby.vim"),"\n")
+  if filereadable(fnameescape(s:rubypath))
+   let s:rubypath= fnameescape(s:rubypath)
+   break
+  endif
+ endfor
+endif
+if (g:vimsyn_embed =~ 'r' && has("ruby")) && filereadable(s:rubypath)
+ unlet! b:current_syntax
+ exe "syn include @vimRubyScript ".s:rubypath
+ VimFoldr syn region vimRubyRegion matchgroup=vimScriptDelim start=+rub[y]\s*<<\s*\z(.*\)$+ end=+^\z1$+	contains=@vimRubyScript
+ syn region vimRubyRegion matchgroup=vimScriptDelim start=+rub[y]\s*<<\s*$+ end=+\.$+		contains=@vimRubyScript
+ syn cluster vimFuncBodyList	add=vimRubyRegion
+else
+ syn region vimEmbedError start=+rub[y]\s*<<\s*\z(.*\)$+ end=+^\z1$+
+ syn region vimEmbedError start=+rub[y]\s*<<\s*$+ end=+\.$+
+endif
+unlet s:rubypath
+
+" [-- python --] {{{3
+let s:pythonpath= fnameescape(expand("<sfile>:p:h")."/python.vim")
+if !filereadable(s:pythonpath)
+ for s:pythonpath in split(globpath(&rtp,"syntax/python.vim"),"\n")
+  if filereadable(fnameescape(s:pythonpath))
+   let s:pythonpath= fnameescape(s:pythonpath)
+   break
+  endif
+ endfor
+endif
+if g:vimsyn_embed =~ 'P' && (has("python") || has("python3")) && filereadable(s:pythonpath)
+ unlet! b:current_syntax
+ exe "syn include @vimPythonScript ".s:pythonpath
+ VimFoldP syn region vimPythonRegion matchgroup=vimScriptDelim start=+py\%[thon]3\=\s*<<\s*\z(.*\)$+ end=+^\z1$+	contains=@vimPythonScript
+ VimFoldP syn region vimPythonRegion matchgroup=vimScriptDelim start=+py\%[thon]3\=\s*<<\s*$+ end=+\.$+		contains=@vimPythonScript
+ VimFoldP syn region vimPythonRegion matchgroup=vimScriptDelim start=+Py\%[thon]2or3\s*<<\s*\z(.*\)$+ end=+^\z1$+		contains=@vimPythonScript
+ VimFoldP syn region vimPythonRegion matchgroup=vimScriptDelim start=+Py\%[thon]2or3\=\s*<<\s*$+ end=+\.$+		contains=@vimPythonScript
+ syn cluster vimFuncBodyList	add=vimPythonRegion
+else
+ syn region vimEmbedError start=+py\%[thon]3\=\s*<<\s*\z(.*\)$+ end=+^\z1$+
+ syn region vimEmbedError start=+py\%[thon]3\=\s*<<\s*$+ end=+\.$+
+endif
+unlet s:pythonpath
+
+" [-- tcl --] {{{3
+if has("win32") || has("win95") || has("win64") || has("win16")
+ " apparently has("tcl") has been hanging vim on some windows systems with cygwin
+ let s:trytcl= (&shell !~ '\<\%(bash\>\|4[nN][tT]\|\<zsh\)\>\%(\.exe\)\=$')
+else
+ let s:trytcl= 1
+endif
+if s:trytcl
+ let s:tclpath= fnameescape(expand("<sfile>:p:h")."/tcl.vim")
+ if !filereadable(s:tclpath)
+  for s:tclpath in split(globpath(&rtp,"syntax/tcl.vim"),"\n")
+   if filereadable(fnameescape(s:tclpath))
+    let s:tclpath= fnameescape(s:tclpath)
+    break
+   endif
+  endfor
+ endif
+ if (g:vimsyn_embed =~ 't' && has("tcl")) && filereadable(s:tclpath)
+  unlet! b:current_syntax
+  exe "syn include @vimTclScript ".s:tclpath
+  VimFoldt syn region vimTclRegion matchgroup=vimScriptDelim start=+tc[l]\=\s*<<\s*\z(.*\)$+ end=+^\z1$+	contains=@vimTclScript
+  VimFoldt syn region vimTclRegion matchgroup=vimScriptDelim start=+tc[l]\=\s*<<\s*$+ end=+\.$+	contains=@vimTclScript
+  syn cluster vimFuncBodyList	add=vimTclScript
+ else
+  syn region vimEmbedError start=+tc[l]\=\s*<<\s*\z(.*\)$+ end=+^\z1$+
+  syn region vimEmbedError start=+tc[l]\=\s*<<\s*$+ end=+\.$+
+ endif
+ unlet s:tclpath
+else
+ syn region vimEmbedError start=+tc[l]\=\s*<<\s*\z(.*\)$+ end=+^\z1$+
+ syn region vimEmbedError start=+tc[l]\=\s*<<\s*$+ end=+\.$+
+endif
+unlet s:trytcl
+
+" [-- mzscheme --] {{{3
+let s:mzschemepath= fnameescape(expand("<sfile>:p:h")."/scheme.vim")
+if !filereadable(s:mzschemepath)
+ for s:mzschemepath in split(globpath(&rtp,"syntax/mzscheme.vim"),"\n")
+  if filereadable(fnameescape(s:mzschemepath))
+   let s:mzschemepath= fnameescape(s:mzschemepath)
+   break
+  endif
+ endfor
+endif
+if (g:vimsyn_embed =~ 'm' && has("mzscheme")) && filereadable(s:mzschemepath)
+ unlet! b:current_syntax
+ let iskKeep= &isk
+ exe "syn include @vimMzSchemeScript ".s:mzschemepath
+ let &isk= iskKeep
+ VimFoldm syn region vimMzSchemeRegion matchgroup=vimScriptDelim start=+mz\%[scheme]\s*<<\s*\z(.*\)$+ end=+^\z1$+	contains=@vimMzSchemeScript
+ VimFoldm syn region vimMzSchemeRegion matchgroup=vimScriptDelim start=+mz\%[scheme]\s*<<\s*$+ end=+\.$+		contains=@vimMzSchemeScript
+ syn cluster vimFuncBodyList	add=vimMzSchemeRegion
+else
+ syn region vimEmbedError start=+mz\%[scheme]\s*<<\s*\z(.*\)$+ end=+^\z1$+
+ syn region vimEmbedError start=+mz\%[scheme]\s*<<\s*$+ end=+\.$+
+endif
+unlet s:mzschemepath
+
+" Synchronize (speed) {{{2
+"============
+if exists("g:vimsyn_minlines")
+ exe "syn sync minlines=".g:vimsyn_minlines
+endif
+if exists("g:vimsyn_maxlines")
+ exe "syn sync maxlines=".g:vimsyn_maxlines
+else
+ syn sync maxlines=60
+endif
+syn sync linecont	"^\s\+\\"
+syn sync match vimAugroupSyncA	groupthere NONE	"\<aug\%[roup]\>\s\+[eE][nN][dD]"
+
+" ====================
+" Highlighting Settings {{{2
+" ====================
+
+if !exists("g:vimsyn_noerror")
+ hi def link vimBehaveError	vimError
+ hi def link vimCollClassErr	vimError
+ hi def link vimErrSetting	vimError
+ hi def link vimEmbedError	vimError
+ hi def link vimFTError	vimError
+ hi def link vimFunctionError	vimError
+ hi def link vimFunc         	vimError
+ hi def link vimHiAttribList	vimError
+ hi def link vimHiCtermError	vimError
+ hi def link vimHiKeyError	vimError
+ hi def link vimKeyCodeError	vimError
+ hi def link vimMapModErr	vimError
+ hi def link vimSubstFlagErr	vimError
+ hi def link vimSynCaseError	vimError
+ hi def link vimBufnrWarn	vimWarn
+endif
+
+hi def link vimAbb	vimCommand
+hi def link vimAddress	vimMark
+hi def link vimAugroupError	vimError
+hi def link vimAugroupKey	vimCommand
+hi def link vimAuHighlight	vimHighlight
+hi def link vimAutoCmdOpt	vimOption
+hi def link vimAutoCmd	vimCommand
+hi def link vimAutoEvent	Type
+hi def link vimAutoSet	vimCommand
+hi def link vimBehaveModel	vimBehave
+hi def link vimBehave	vimCommand
+hi def link vimBracket	Delimiter
+hi def link vimCmplxRepeat	SpecialChar
+hi def link vimCommand	Statement
+hi def link vimComment	Comment
+hi def link vimCommentString	vimString
+hi def link vimCommentTitle	PreProc
+hi def link vimCondHL	vimCommand
+hi def link vimContinue	Special
+hi def link vimCtrlChar	SpecialChar
+hi def link vimEchoHLNone	vimGroup
+hi def link vimEchoHL	vimCommand
+hi def link vimElseIfErr	Error
+hi def link vimElseif	vimCondHL
+hi def link vimEnvvar	PreProc
+hi def link vimError	Error
+hi def link vimFBVar	vimVar
+hi def link vimFgBgAttrib	vimHiAttrib
+hi def link vimFold	Folded
+hi def link vimFTCmd	vimCommand
+hi def link vimFTOption	vimSynType
+hi def link vimFuncKey	vimCommand
+hi def link vimFuncName	Function
+hi def link vimFuncSID	Special
+hi def link vimFuncVar	Identifier
+hi def link vimGroupAdd	vimSynOption
+hi def link vimGroupName	vimGroup
+hi def link vimGroupRem	vimSynOption
+hi def link vimGroupSpecial	Special
+hi def link vimGroup	Type
+hi def link vimHiAttrib	PreProc
+hi def link vimHiClear	vimHighlight
+hi def link vimHiCtermFgBg	vimHiTerm
+hi def link vimHiCTerm	vimHiTerm
+hi def link vimHighlight	vimCommand
+hi def link vimHiGroup	vimGroupName
+hi def link vimHiGuiFgBg	vimHiTerm
+hi def link vimHiGuiFont	vimHiTerm
+hi def link vimHiGuiRgb	vimNumber
+hi def link vimHiGui	vimHiTerm
+hi def link vimHiNmbr	Number
+hi def link vimHiStartStop	vimHiTerm
+hi def link vimHiTerm	Type
+hi def link vimHLGroup	vimGroup
+hi def link vimHLMod	PreProc
+hi def link vimInsert	vimString
+hi def link vimKeyCode	vimSpecFile
+hi def link vimKeyword	Statement
+hi def link vimLet	vimCommand
+hi def link vimLineComment	vimComment
+hi def link vimMapBang	vimCommand
+hi def link vimMapModKey	vimFuncSID
+hi def link vimMapMod	vimBracket
+hi def link vimMap	vimCommand
+hi def link vimMark	Number
+hi def link vimMarkNumber	vimNumber
+hi def link vimMenuMod	vimMapMod
+hi def link vimMenuNameMore	vimMenuName
+hi def link vimMenuName	PreProc
+hi def link vimMtchComment	vimComment
+hi def link vimNorm	vimCommand
+hi def link vimNotation	Special
+hi def link vimNotFunc	vimCommand
+hi def link vimNotPatSep	vimString
+hi def link vimNumber	Number
+hi def link vimOperError	Error
+hi def link vimOper	Operator
+hi def link vimOption	PreProc
+hi def link vimParenSep	Delimiter
+hi def link vimPatSepErr	vimPatSep
+hi def link vimPatSepR	vimPatSep
+hi def link vimPatSep	SpecialChar
+hi def link vimPatSepZone	vimString
+hi def link vimPatSepZ	vimPatSep
+hi def link vimPattern	Type
+hi def link vimPlainMark	vimMark
+hi def link vimPlainRegister	vimRegister
+hi def link vimRegister	SpecialChar
+hi def link vimScriptDelim	Comment
+hi def link vimSearchDelim	Statement
+hi def link vimSearch	vimString
+hi def link vimSep	Delimiter
+hi def link vimSetMod	vimOption
+hi def link vimSetSep	Statement
+hi def link vimSetString	vimString
+hi def link vimSpecFile	Identifier
+hi def link vimSpecFileMod	vimSpecFile
+hi def link vimSpecial	Type
+hi def link vimStatement	Statement
+hi def link vimStringCont	vimString
+hi def link vimString	String
+hi def link vimSubst1	vimSubst
+hi def link vimSubstDelim	Delimiter
+hi def link vimSubstFlags	Special
+hi def link vimSubstSubstr	SpecialChar
+hi def link vimSubstTwoBS	vimString
+hi def link vimSubst	vimCommand
+hi def link vimSynCaseError	Error
+hi def link vimSynCase	Type
+hi def link vimSyncC	Type
+hi def link vimSyncError	Error
+hi def link vimSyncGroupName	vimGroupName
+hi def link vimSyncGroup	vimGroupName
+hi def link vimSyncKey	Type
+hi def link vimSyncNone	Type
+hi def link vimSynContains	vimSynOption
+hi def link vimSynError	Error
+hi def link vimSynKeyContainedin	vimSynContains
+hi def link vimSynKeyOpt	vimSynOption
+hi def link vimSynMtchGrp	vimSynOption
+hi def link vimSynMtchOpt	vimSynOption
+hi def link vimSynNextgroup	vimSynOption
+hi def link vimSynNotPatRange	vimSynRegPat
+hi def link vimSynOption	Special
+hi def link vimSynPatRange	vimString
+hi def link vimSynRegOpt	vimSynOption
+hi def link vimSynRegPat	vimString
+hi def link vimSynReg	Type
+hi def link vimSyntax	vimCommand
+hi def link vimSynType	vimSpecial
+hi def link vimTodo	Todo
+hi def link vimUnmap	vimMap
+hi def link vimUserAttrbCmpltFunc	Special
+hi def link vimUserAttrbCmplt	vimSpecial
+hi def link vimUserAttrbKey	vimOption
+hi def link vimUserAttrb	vimSpecial
+hi def link vimUserAttrbError	Error
+hi def link vimUserCmdError	Error
+hi def link vimUserCommand	vimCommand
+hi def link vimUserFunc	Normal
+hi def link vimVar	Identifier
+hi def link vimWarn	WarningMsg
+
+" Current Syntax Variable: {{{2
+let b:current_syntax = "vim"
+
+" ---------------------------------------------------------------------
+" Cleanup: {{{1
+delc VimFolda
+delc VimFoldf
+delc VimFoldl
+delc VimFoldm
+delc VimFoldp
+delc VimFoldP
+delc VimFoldr
+delc VimFoldt
+let &cpo = s:keepcpo
+unlet s:keepcpo
+" vim:ts=18 fdm=marker ft=vim