BandBCrosses

//Bees and Bombs
//Sept. 26, 2018

int[][] result;
float t, c;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3), ia = atan(sqrt(.5));

void push() {
  pushMatrix();
  pushStyle();
}

void pop() {
  popStyle();
  popMatrix();
}

float c01(float g) {
  return constrain(g, 0, 1);
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    c = mouseY*1.0/height;
    if (mousePressed)
      println(c);
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    c = 0;
    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 4;
int numFrames = 360;        
float shutterAngle = .6;

boolean recording = false;

void setup() {
  size(720, 720, P3D);
  pixelDensity(recording ? 1 : 2);
  smooth(8);
  result = new int[width*height][3];
  rectMode(CENTER);
  fill(32);
  noStroke();
}

float x, y, z, tt;
int N = 12;
float w = 44, h= w*3, sp = h;

void cros() {
  rect(0, 0, w, h);
  rect(0, 0, h, w);
}

void draw_() {
  push();
  translate(width/2, height/2);

  if (3*t < 1) {
    t = 3*t;

    background(234); 
    fill(34);

    for (int i=-N; i<=N; i++) {
      for (int j=-N; j<=N; j++) {
        tt = ease(t, 3);
        push();
        translate(i*h - j*w*tt, j*h + i*w*tt);
        rotate(HALF_PI*tt);
        cros();
        pop();
      }
    }
  } 
  
  else if (3*t < 2) {
    t = 3*t - 1;

    background(34);
    fill(234);

    push();
    scale(-1, 1);
    for (int i=-N; i<=N; i++) {
      for (int j=-N; j<=N; j++) {
        tt = 1-ease(t, 3);
        push();
        translate((i+.5)*h + (j+.5)*w*tt, (j+.5)*h - (i+.5)*w*tt);
        rotate(-HALF_PI*tt);
        cros();
        pop();
      }
    }
    pop();
  } 
  
  else {
    t = 3*t - 2;

    background(t>.5?34:234);
    fill(t>.5?234:34);
    
    for (int i=-N; i<=N; i++) {
      for (int j=-N; j<=N; j++) {
        tt = ease(t, 3);
        push();
        translate((i+.5*(t>.5?1:0))*h, (j+.5*(t>.5?1:0))*h);
        rotate(HALF_PI*tt);
        scale(map(cos(TWO_PI*tt), 1, -1, 1, sqrt(2)*3/4));
        rect(0, 0, 2*w, 2*w);
        pop();
      }
    }
  }
  pop();
}