release.nix

let
  bootstrap = import <nixpkgs> {};

  nixpkgs = builtins.fromJSON (builtins.readFile ./nixpkgs.json);

  src = bootstrap.fetchFromGitHub {
    owner = "NixOS";
    repo  = "nixpkgs";
    inherit (nixpkgs) rev sha256;
  };

  config = {
    allowUnfree = true;
    packageOverrides = pkgs: rec {
      haskellPackages = pkgs.haskellPackages.override {
        overrides = haskellPackagesNew: haskellPackagesOld: rec {
          validation = pkgs.haskell.lib.dontCheck haskellPackagesOld.validation;
        };
      };
    };
  };

  pkgs = import src { inherit config; };

  gems = pkgs.bundlerEnv {
    name = "backend-tooling";
    ruby = pkgs.ruby;
    gemdir = ./.;
  };

in with pkgs; {
  project = haskell.lib.overrideCabal
              (haskellPackages.callCabal2nix "haskell-ruby-test" ./. {})
              ( drv: {
                  buildDepends = (drv.buildDepends or []) ++ [ gems ruby ];
                  doHaddock = false;
                  doCheck = false;
                }
              );
}