Run ExUnit test in kitty with joyride

exunit-kitty.cljs

(ns kitty
  (:require ["vscode" :as vscode]
            [joyride.core :as joyride]
            ["child_process" :as child-process]))

;; This script runs the selected ExUnit test in a kitty terminal
;; as `mix test <file>:<line>`
;; requires kitty to be started as `kitty --listen-on unix:/tmp/mykitty`

;; config the unix channel where kitty is accessed
(def kitty "kitty @ --to unix:/tmp/mykitty ")

(def exec (.-exec child-process))
(defn root-path [] (. vscode.workspace -rootPath))

;; select a kitty window with cwd matching the project root
(def window-selector (str " --match cwd:" (root-path) " "))

(defn file-path [] 
  (let [root (root-path)
        path (. vscode.window.activeTextEditor.document -fileName)]
    (if (.startsWith path root)
      (.replace path (str root "/") "")
      path)))

(defn line-number [] (. vscode.window.activeTextEditor.selection.active -line))

(defn focus
  []
  (exec (str kitty "focus-window" window-selector)))

(defn send-text
  [text]
  (exec (str kitty "send-text" window-selector text)))

(defn send-command
  [command]
  (send-text (str "\"" command "\n\"")))

(defn my-main []
  (send-command (str "mix test " (file-path) ":" (line-number) "\n"))
  (focus))

(when (joyride/invoked-script)
  (my-main))