Nix packages for xtables-addons

xtables-addons-kmod.nix

{ stdenv, lib, linuxPackages, kernel ? linuxPackages.kernel, kmod }:

let
  kbuilddir = "${kernel.dev}/lib/modules/${kernel.modDirVersion}/build";
in
stdenv.mkDerivation rec {
  name = "xtables-addons-kmod-${version}-${kernel.version}";
  version = "3.24";

  src = fetchTarball {
    url = "https://inai.de/files/xtables-addons/xtables-addons-${version}.tar.xz";
  };

  hardeningDisable = [ "pic" ];

  nativeBuildInputs = kernel.moduleBuildDependencies;

  configurePhase = "true";

  buildPhase = ''
    make -j$(nproc) -C ${kbuilddir} M=$PWD/extensions XA_ABSTOPSRCDIR=$PWD modules
  '';

  installPhase = ''
    mkdir $out
    make -C ${kbuilddir} M=$PWD/extensions XA_ABSTOPSRCDIR=$PWD INSTALL_MOD_PATH=$out modules_install
  '';

  meta = with lib; {
    description = "Additional extensions for Xtables packet filter (kernel module)";
    homepage = "https://inai.de/projects/xtables-addons/";
    license = licenses.gpl2;
    platforms = platforms.linux;
  };
}

xtables-addons-usermod.nix

{ stdenv, lib, iptables, pkgconfig }:

stdenv.mkDerivation rec {
  pname = "xtables-addons-usermod";
  version = "3.24";

  libraries = [
    iptables
    pkgconfig
  ];

  buildInputs = libraries;

  src = fetchTarball {
    url = "https://inai.de/files/xtables-addons/xtables-addons-${version}.tar.xz";
  };

  configureFlags = [
    "--with-xtlibdir=$(out)/lib/xtables"
    "--without-kbuild"
  ];

  enableParallelBuilding = true;  

  meta = with lib; {
    description = "Additional extensions for Xtables packet filter (userspace libraries)";
    homepage = "https://inai.de/projects/xtables-addons/";
    license = licenses.gpl2;
  };
}