core.cljs

(ns perun.core
  (:require-macros [cljs.core.async.macros :refer [go]])
  (:require [om.core :as om :include-macros true]
            [cljs.core.async :refer [<!]]
            [om-tools.core :refer-macros [defcomponent]]
            [om-tools.dom :as dom :include-macros true]
            [perun.elasticsearch :as es]))

(enable-console-print!)

(def app-state (atom {:events []
                      :query "*"}))

(defn update-events! [app result]
  (om/transact! app :events #(.. result -hits -hits)))

(defn search [app owner]
  (let [input (-> (om/get-node owner "query")
                  .-value)
        query (if (empty? input) "*" input)
        [succ _] (es/search {:q query})]
    (go (let [result (<! succ)]
          (om/transact! app :query (fn [] query))
          (update-events! app result)))))

(defcomponent event-view [event owner]
  (render [_]
          (dom/li (js/JSON.stringify event))))

(defcomponent events-view [app owner]
  (will-mount [_]
              (let [[succ _] (es/search {:q (:query app)})]
                (go (update-events! app (<! succ)))))
  (render [_]
          (dom/div
            (dom/div {:id "#form"}
                     (dom/input {:default-value (:query app)
                                 :type "text"
                                 :ref "query"})
                     (dom/button {:on-click #(search app owner)} "Search"))
            (dom/ul (om/build-all event-view (:events app))))))

(om/root
  events-view
  app-state
  {:target (. js/document (getElementById "app"))})