kody.scm

(define (foldr func init lst)
  (if (null? lst)
    init
    (func (car lst) (foldr func init (cdr lst)))))

(define (foldl func init lst)
  (if (null? lst)
    init
    (foldl func (func (car lst) init) (cdr lst))))

(define (koduj-alfabetycznie val lst)
  (foldl (lambda (v acc) (if (equal? val (car v))
                           (cdr v)
                           acc)) val lst))

(define (odwroc-alfabet lst)
  (map (lambda (pair) (cons (cdr pair) (car pair))) lst))

(define (alfabetyczny-koder lst)
  (lambda (val)
    (koduj-alfabetycznie val lst)))

(define (square x) (* x x))

(define (expmod base exp m)
  (cond ((= exp 0) 1)
        ((even? exp) (remainder (square (expmod base (/ exp 2) m)) m))
        (else (remainder (* base (expmod base (- exp 1) m)) m))))

(define (egcd a b)
  (if (zero? b)
    (list a 1 0)
    (let* ((prev (egcd b (modulo a b)))
           (g (car prev))
           (x (cadr prev))
           (y (caddr prev)))
      (list g y (- x (* y (quotient a b)))))))

(define (modinv a m)
  (let ((ret (egcd a m)))
    (if (= (car ret) 1)
      (modulo (cadr ret) m)
      #f)))

(define (max-coprime-upto val a)
  (cond ((= a 1) 1)
        ((= (car (egcd a val)) 1) a)
        (else (max-coprime-upto val (- a 1)))))

(define (generuj-klucze p q x)
  (let* ((n (* p q))
         (tmp (* (- p 1) (- q 1)))
         (e (max-coprime-upto tmp x))
         (s (modinv e tmp)))
    (cons (cons n e) (cons n s))))

(define (rsa-koder key)
  (lambda (val) (expmod val (cdr key) (car key))))

(define (koduj lst f)
  (map f lst))

(define (p/q-koder lst)
  (lambda (init) (foldr (lambda (val acc) (+ val (/ 1 acc))) init lst)))

(define (p/q-dekoder lst)
  (lambda (init) (foldl (lambda (val acc) (/ 1 (- acc val))) init lst)))

(define (komponuj lst)
  (lambda (init) (foldl (lambda (f acc) (f acc)) init lst)))