PKGBUILD

# Contributor: Alessio 'Bl@ster' Biancalana <dottorblaster@gmail.com>

pkgname=docky-bzr
pkgver=1477
pkgrel=1
pkgdesc="The Finest Dock No Money Can Buy"
url="https://launchpad.net/docky"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gnome-desktop-sharp' 'gnome-keyring-sharp' 'gtk2' 'mono-addins'
         'hicolor-icon-theme' 'ndesk-dbus-glib' 'notify-sharp-svn' 'xdg-utils'
         'gio-sharp' 'dockmanager')
makedepends=('bzr' 'intltool' 'gettext')
conflicts=(docky)
provides=("docky=2.1.0")
options=('!libtool' '!emptydirs')
install=docky.install

_bzrtrunk=lp:docky
_bzrmod=docky

build() {
  cd "$srcdir"

  msg2 "Connecting to Launchpad...."

  if [ -d $_bzrmod ] ; then
    ( cd $_bzrmod && bzr up )
  else
    bzr checkout $_bzrtrunk $_bzrmod
  fi

  msg2 "BZR checkout done or server timeout"

  rm -rf $_bzrmod-build
  cp -r $_bzrmod $_bzrmod-build
  cd $_bzrmod-build

  msg2 "Starting make..."

  export MONO_SHARED_DIR=${srcdir}/.wabi
  mkdir -p ${MONO_SHARED_DIR}

  ./autogen.sh \
    --prefix=/usr \
    --sysconfdir=/etc || return 1

  make || return 1
}

package() {
  cd "$srcdir/$_bzrmod-build"

  make DESTDIR="$pkgdir" GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 install || return 1

  mkdir -p "$pkgdir/usr/share/gconf/schemas"
  gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/docky.schemas" "$pkgdir"/etc/gconf/schemas/*.schemas || return 1
  rm -rf "$pkgdir/etc/gconf"
}