PKGBUILD

# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: Eduardo Romero <eduardo@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>

_pkgbasename=wine
pkgver=1.2
pkgrel=2

pkgname=$_pkgbasename-wow64
_pkgbasever=${pkgver/rc/-rc}

pkgdesc="A compatibility layer for running Windows programs (both 32-bit and 64-bit)"
url="http://www.winehq.com"
arch=(x86_64)
license=(LGPL)
provides=("wine=$pkgver" "bin32-wine=$pkgver")
conflicts=(wine bin32-wine)

depends=(
  fontconfig      lib32-fontconfig
  mesa            lib32-mesa 
  libxcursor      lib32-libxcursor
  libxrandr       lib32-libxrandr
  libxdamage      lib32-libxdamage
  libxxf86dga     lib32-libxxf86dga
  alsa-lib        lib32-alsa-lib
)

makedepends=(autoconf ncurses bison perl fontforge flex
  'gcc>=4.5.0-2'  cross32-gcc
                  lib32-glibc-devel-il
  libgphoto2
  giflib          lib32-giflib
  libxpm          lib32-libxpm
  libpng          lib32-libpng
  libxinerama     lib32-libxinerama
  libxcomposite   lib32-libxcomposite
  libxmu          lib32-libxmu
  libxxf86vm      lib32-libxxf86vm
  libxml2         lib32-libxml2
  libxslt         lib32-libxslt
  libldap         lib32-libldap
  lcms            lib32-lcms
  mpg123          lib32-mpg123
  openal          lib32-openal
  esound          lib32-esound
  jack            lib32-jack
  cups            lib32-libcups
  sane
  samba
)
  
optdepends=(
  libgphoto2
  giflib        lib32-giflib
  libpng        lib32-libpng
  libldap       lib32-libldap
  lcms          lib32-lcms
  libxml2       lib32-libxml2
  mpg123        lib32-mpg123
  openal        lib32-openal
  esound        lib32-esound
  jack          lib32-jack
  cups          lib32-libcups
  sane
  samba
)

source=(http://ibiblio.org/pub/linux/system/emulators/$_pkgbasename/$_pkgbasename-$_pkgbasever.tar.bz2)

_libdir32=/opt/lib32/usr/lib
_libdir64=/usr/lib

build() {
  cd "$srcdir"

  # Allow ccache to work
  mv $_pkgbasename-$_pkgbasever $_pkgbasename

  # (Re)create build dirs
  rm -rf $_pkgbasename-{32,64}-build
  mkdir $_pkgbasename-{32,64}-build

### 64-bit build

  msg2 "Building Wine-64..."

  cd "$srcdir/$_pkgbasename-64-build"
  ../$_pkgbasename/configure \
    --prefix=/usr \
    --libdir="$_libdir64" \
    --sysconfdir=/etc \
    --with-x \
    --enable-win64

  make

### 32-bit build

  msg2 "Building Wine-32..."

  cd "$srcdir/$_pkgbasename-32-build"
  ../$_pkgbasename/configure \
     CFLAGS="${CFLAGS/x86-64/i686}" \
     CXXFLAGS="${CXXFLAGS/x86-64/i686}" \
     LDFLAGS="$LDFLAGS -L/opt/lib32/lib -L/opt/lib32/usr/lib" \
     LDD=/usr/bin/ldd32 \
     --host=i686-unknown-linux-gnu \
     --prefix=/usr \
     --libdir="$_libdir32" \
     --sysconfdir=/etc \
     --with-x \
     --with-wine64="$srcdir/$_pkgbasename-64-build"

  make
}

package() {
  cd "$srcdir/$_pkgbasename-32-build"

  make prefix="$pkgdir/usr" \
    libdir="$pkgdir$_libdir32" \
    dlldir="$pkgdir$_libdir32/wine" install

  cd "$srcdir/$_pkgbasename-64-build"

  make prefix="$pkgdir/usr" \
    libdir="$pkgdir$_libdir64" \
    dlldir="$pkgdir$_libdir64/wine" install

  # Directories
  install -d "$pkgdir/etc/wine"
}

md5sums=('eb4e5423b277fc1e77807b04f366f7b7')