Modifying/transforming a Meteor collection cursor in a publication

lists.coffee

# Our minimongoid 'List' class, wrapping the 'lists' Meteor.Collection 
# (runs on server & client). If not using minimongoid, you could simply
# on the server & client use:
#
# Lists = new Meteor.Collection 'lists'

class @List extends Minimongoid
  @_collection: new Meteor.Collection 'lists'

publications.coffee

# Insert into contributed list publication a 'contributed' flag, so we can separate 
# it on the client from favorite, etc lists.

Meteor.publish 'contributedLists', (username) ->
  items = Item.where itemUsername: username

  listIds = _.uniq(_.pluck(items, 'listId'))

  parms =
    _id:
      $in: listIds

  handle = List.find(parms).observeChanges
    added: (id, fields) =>
      fields.contributed = true
      # NB: 'lists' is the name of the Meteor.Collection, not the publication
      @added 'lists', id, fields

    changed: (id, fields) =>
      fields.contributed = true
      @changed 'lists', id, fields

    removed: (id, fields) =>
      @removed 'lists', id

  @ready()
  @onStop -> handle.stop()

routes.coffee

# Subscribe to the publication 'contributedLists', which will bring down 
# contributed lists and merge them with 'lists' Meteor.Collection.

Router.map ->
  @route 'listsIndex',
    path: '/lists'
    waitOn: -> [
      Meteor.subscribe 'lists', Session.get('username')
      Meteor.subscribe 'contributedLists', Session.get('username')
      Meteor.subscribe 'favoritedLists'
    ]