AngularJS directive to disallow non-digits in an input field. Based on http://stackoverflow.com/a/19675023/6962 Done with @tskogberg.

only_digits.coffee

# http://stackoverflow.com/a/19675023/6962

app.directive "onlyDigits", ->
  restrict: "A"
  require: "?ngModel"
  link: (scope, element, attrs, ngModel) ->
    return unless ngModel

    ngModel.$parsers.unshift (inputValue) ->
      digits = inputValue.replace(/\D/g, "")
      ngModel.$viewValue = digits
      ngModel.$render()
      digits

only_digits_spec.coffee

#= require helpers/angular_helper
#= require directives/only_digits

describe "onlyDigits", ->
  $compile = null
  $scope = null
  beforeEach inject (_$compile_, _$rootScope_) ->
    $compile = _$compile_
    $scope = _$rootScope_

  it "strips non-digits from the ng-model value (i.e. doesn't let you input them into a form field)", ->
    formElement = compile """
      <form name="theForm">
        <input name="theField" ng-model="foo" only-digits>
      </form>
    """

    inputElement = formElement.find("input")
    inputModel = $scope.theForm.theField

    inputModel.$setViewValue("123abc")

    expect(inputElement.val()).toEqual("123")


  compile = (html) ->
    element = $compile(html)($scope)
    $scope.$digest()
    element