maven-publish.gradle

ext {
    localProp = new Properties()
    fileName = 'local.properties'
    if (project.rootProject.file(fileName).exists()) {
        localProp.load(new FileInputStream(rootProject.file(fileName)))
    }
    groupName = "br.com.cetelem.android.components"
    publishUsername = System.env.PUBLISH_USERNAME != null ? System.env.PUBLISH_USERNAME : localProp["publishUsername"] ?: ""
    publishPassword = System.env.PUBLISH_PASSWORD != null ? System.env.PUBLISH_PASSWORD : localProp["publishPassword"] ?: ""
    repoUrl = System.env.REPO_URL != null ? System.env.REPO_URL : localProp["repoUrl"] ?: ""
}

if (plugins.hasPlugin("com.android.library")) {

    apply plugin: 'maven-publish'

    if (!project.ext.properties.containsKey("artifactId")) {
        ext.artifactId = project.name
    }

    publishing {
        repositories {
            maven {
                credentials {
                    username publishUsername
                    password publishPassword
                }
                url repoUrl
            }
        }
        publications {
            projectRelease(MavenPublication) {
                artifactId project.artifactId
                groupId groupName
                artifact "build/outputs/aar/${project.name}-release.aar"
                version "${project.getVersion()}"
            }
        }
    }
}