Ejemplo de invocacion dinamica de metodos en groovy

DemoDynamic.groovy

class DemoDynamic {
  Map<String, List<String>> permissions = [:]

  Boolean hasPermission(String name, String permission){
    permission in permissions?."$name"
  }

  Map createPermission(String name, List<String> permissions) {
    this.permissions?."$name" = permissions
    this.permissions
  }

  def dynamicMethods = [[regex:"hasPermission(.*)", method:this.&hasPermission],
  [regex:"create(.*)Permission", method:this.&createPermission]]


  def methodMissing(String name, args) {
    def method = dynamicMethods.find { name =~ it.regex}
    if(method) {
      def match = name =~ method.regex
      return method.method(match[0][1], * args)
    } else
      throw new MissingMethodException(name, DemoDynamic , args)
  }

}

demo = new DemoDynamic()
demo.createHgmiguelPermission(["write","read"])
demo.createOtrosPermission(["read"])

assert demo.hasPermissionHgmiguel("write")
assert !demo.hasPermissionOtros("write")