jquery.textchange.coffee

$.event.special.textchange =
    setup: ->
        $el = $ @
        timer = null
        
        $el.data 'lastValue', getElValue(@)

        handler = (event) =>
            current = getElValue(@)
            lastValue = $el.data 'lastValue'
            
            if current isnt lastValue
                triggerCustomEvent @, 'textchange', event, [lastValue]
                $el.data 'lastValue', current
        
        $el.on 'keyup.textchange', handler
        $el.on 'cut.textchange paste.textchange input.textchange', (event) ->
            clearTimeout timer
            timer = setTimeout ->
                handler event
            , 25

        return

    teardown: ->
        $(@).off '.textchange'

getElValue = (el) ->
    $el = $ el
    return if el.contentEditable is 'true' then $el.html() else $el.val()

triggerCustomEvent = (obj, eventType, event, data) ->
    originalType = event.type
    event.type = eventType
    $.event.dispatch.call obj, event, data
    event.type = originalType

Sweet, I'll test for all my cases when I get a chance... Copy/paste, repeated key strokes should trigger, delete/backspace, IE9.