Skip to content

Instantly share code, notes, and snippets.

@holyjak

holyjak/plot-usage.gp

Last active Jul 28, 2020
Embed
What would you like to do?
Gnuplot script to plot memory, CPU usage of a process from `top`
#!/usr/bin/env -S gnuplot --persist -c
# Plot memory and CPU usage over time. Usage:
# usage-plot.gp <input file> [<output .png file>]
# where the input file has the columns `<unix time> <memory, with m/g suffix> <% cpu>`
# To create the input file, see https://gist.github.com/jakubholynet/931a3441982c833f5f8fcdcf54d05c91
# Arguments:
infile=ARG1
outfile=ARG2
set term x11
set title 'Memory, CPU usage from' . infile
set xdata time
set timefmt "%s"
set xlabel "Time [[hh:]mm:ss]"
set ylabel "Memory usage"
set format y '%.1s%cB'
set y2label 'CPU usage'
set format y2 '%.0s%%'
set y2tics nomirror
set tics out
set autoscale y
set autoscale y2
# Credit: Christoph @ https://stackoverflow.com/a/52822256/204205
resolveUnit(s)=(pos=strstrt("kmgtp",s[strlen(s):*]), real(s)*(1024**pos))
if (exists("outfile") && strlen(outfile) > 0) {
print "Outputting to the file ", outfile
set term png # 640,480
set output outfile
}
# Styling
set style line 1 linewidth 2 linecolor 'blue'
set style line 2 linecolor 'light-green'
#set xtics font ", 10"
set tics font ", 10"
set xtics rotate 60 # put label every 60s, make vertical so they don't clash in .png if too many
plot infile u 1:3 with lp axes x1y2 title "cpu" linestyle 2, \
infile using 1:(resolveUnit(stringcolumn(2))) with linespoints title "memory" linestyle 1
@Dhaour9x

This comment has been minimized.

Copy link

@Dhaour9x Dhaour9x commented Jul 21, 2020

Thank you
I have tried this code but I got the following issue:
fsd@ubuntu:~$ ./usage-plot.gp top.dat top.png
/usr/bin/env: ‘gnuplot --persist -c’: No such file or directory

I appreciate your help

@holyjak

This comment has been minimized.

Copy link
Owner Author

@holyjak holyjak commented Jul 21, 2020

@Dhaour9x

This comment has been minimized.

Copy link

@Dhaour9x Dhaour9x commented Jul 21, 2020

yes,

fsd@ubuntu:~$ gnuplot

	G N U P L O T
	Version 5.0 patchlevel 3    last modified 2016-02-21 

	Copyright (C) 1986-1993, 1998, 2004, 2007-2016
	Thomas Williams, Colin Kelley and many others

	gnuplot home:     http://www.gnuplot.info
	faq, bugs, etc:   type "help FAQ"
	immediate help:   type "help"  (plot window: hit 'h')

Terminal type set to 'qt'
gnuplot> 

I'm a bit confused, can you please give me more detailed instructions, which setps do I have to do to make this work. In you blog I don't really understand the steps.
Thank you

@holyjak

This comment has been minimized.

Copy link
Owner Author

@holyjak holyjak commented Jul 22, 2020

@ricksorensen

This comment has been minimized.

Copy link

@ricksorensen ricksorensen commented Jul 26, 2020

On linux the use -S option to split the env command args ('gnuplot --persist -c') into separate parts .. the default is to use all data after env concatenated as command. EG:
#!/usr/bin/env -S gnuplot --persist -c

@holyjak

This comment has been minimized.

Copy link
Owner Author

@holyjak holyjak commented Jul 27, 2020

Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment