BatchRename.bat

@echo off
SETLOCAL
title BatchRename.bat
echo ----------------------------------------------------------------------------------------
echo Script : BatchRename.bat
echo Description : Rename all files in directory using user-defined prefix.
echo Note : Entering certain characters in the prefix will cause errors (/,\,:,^?,^",^<,^>,^|)
echo ----------------------------------------------------------------------------------------


set /A fileCounter=0
set /p filePrefix="Input Prefix: "
for /f "tokens=* delims=" %%f in ('dir /b /a-d') do (
    IF not %%f==BatchRename.bat call :RenameFileAndIncrement "%%f"
)
GOTO ProcessComplete


:RenameFileAndIncrement
SET "oldFileName=%~1"
for /f "tokens=2 delims=." %%a in ("%oldFileName%") do set fileExtension=%%a
set "newFileName=%filePrefix%%fileCounter%.%fileExtension%"
echo Renaming "%oldFileName%" to "%newFileName%"
MOVE "%oldFileName%" "%newFileName%"
set /A fileCounter=fileCounter+1
exit /b

:ProcessComplete
echo Batch Renaming is Complete...
ENDLOCAL
pause
exit