Very simple logger to instrument objects and methods

logger.coffee

logger =
  _anonymousIndex: 0

  guessMethodName: (method) ->
    unless (res = (->).toString.call(method).match(/function([^\(]*)/)[1].replace(/(^\s+|\s+)$/g, ''))
      res = logger.autoNamespace()
    res

  autoNamespace: ->
    "[anonymous##{ ++logger._anonymousIndex }]"

  instrumentMethod: (method, name = logger.guessMethodName(method)) ->
    name = name.replace /\.prototype\./g, '#'
    console.log "[logger] instrumenting method #{ name }..."
    newMethod = ->
      isNew = @constructor is newMethod
      arrow = if isNew then '== new ==' else '== ( ) =='
      console.log "[logger] =#{ arrow }> entering #{ name }"
      try
        res = method.apply @, arguments
      catch err
        console.warn "[logger] !! #{ name } threw #{ err }"
        err.captureStackTrace()
        throw err
      console.log "[logger] <#{ arrow }= exiting #{ name }"
      res
    newMethod.prototype = method.prototype
    for own k, v of method
      newMethod[k] = v
    newMethod

  instrumentObject: (object, namespace = logger.autoNamespace()) ->
    for own k, v of object when typeof v is 'function'
      object[k] = @instrumentMethod v, "#{ namespace }.#{ k }"
    @

module.exports = logger

I was having hard time finding where was happening a silent error in some async workflow so I wrote this, maybe it could be useful for someone else so here it is.

The goal is to instrument existing classes, objects and methods so that it logs when it enter the method, exit it and when an error is triggered by it:

// require('coffee-script/register');
var logger = require('/path/to/logger');

logger.instrumentObject(PassportConnection.prototype, 'PassportConnection.prototype');

second argument is strongly recommended to have easy reading output.

then you get something like that in the console:

[logger] === ( ) ==> entering PassportConnection#parseQuery
[logger] <== ( ) === exiting PassportConnection#parseQuery
[logger] === ( ) ==> entering PassportConnection#lookupPassportRecord
[logger] <== ( ) === exiting PassportConnection#lookupPassportRecord
[logger] === ( ) ==> entering PassportConnection#createUserRecord
[logger] <== ( ) === exiting PassportConnection#createUserRecord
...