pkgbuild

# Maintainer: Butui Hu <hot123tea123@gmail.com>

pkgname=netron
pkgver=2.9.8
pkgrel=1
pkgdesc="Visualizer for deep learning and machine learning models "
arch=('x86_64')
url='https://github.com/lutzroeder/Netron'
license=('MIT')
depends=('electron' 'python' 'nodejs')
makedepends=('git' 'npm' 'python2')
source=(
    "${pkgname}-${pkgver}.tar.gz::https://github.com/lutzroeder/netron/archive/v${pkgver}.tar.gz"
    'netron.desktop'
    'netron.sh'
)
sha512sums=('c553715dd2767b97b4a5d632d1e4399ad8b7263c01bcdf63c197db7fecdf1f0b09bf625cf556636823d610464ddac0561ce802a57ea9cd752442a1726b89c7a8'
            '17eb56c6a5b77c85bf3cdaa847f2ce2972a6f71637bf7981eea999ca1d0b4fc9f53b113adf356b93fe15d0734c060f95eee2dd91baede631e27da17140c07917'
            '7feb1fe501b4cd34d6158b1fe87949ab965a0583a7ec45115c16fbc1edf1d1b2581eb95b7d51ee98a5dc1a6890d790019421b335047ef759c05bee03329d7a10')

prepare() {
    cd "${pkgname}-${pkgver}"
    # remove Electron bundle
    sed -i '/"electron\(-packager\)*":/d' package.json
}

build() {
    cd "${pkgname}-${pkgver}"
#    PYTHON=/usr/bin/python2 npm install
    npm install
    # npm run build:linux64
}

package() {
    install -Dm644 netron.desktop -t "${pkgdir}/usr/share/applications"

    cd "${pkgname}-${pkgver}"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

    rm -rfv scripts
    mkdir -p "${pkgdir}/usr/lib/${pkgname}"
    cp -r --no-preserve='ownership' -- * "${pkgdir}/usr/lib/${pkgname}"
    install -Dm644 "${srcdir}/${pkgname}-${pkgver}/media/logo.png" "${pkgdir}/usr/share/icons/netron.png" 
    install -Dm755 "${srcdir}/netron.sh" "${pkgdir}/usr/bin/netron"
}
# vim:set ts=2 sw=2 et: