Ring: from the ground up

general-case-middleware.clj

(defn wrap-generic-middleware-example [handler & [other-args]]
  (fn [request]
    ;; Early side-effects:
    (log/info "Wrapping incoming request...")
    (let [;; Modify request here:
          req (assoc request :new-req-key "some value for handlers")
          ;; Run the handlers:
          resp (handler req)]
      ;; Late side-effects:
      (log/info "My middleware is almost done.")
      ;; Modify and return the response here:
      (assoc resp :some-key "some value"))))

handler-function.clj

(defn hello-world-handler [req]
  {:status 200
   :headers {"content-type" "text/plain"}
   :body (format "Hello, %s!\n" (:remote-addr req))})

(def request {:remote-addr "12.34.56.78" :uri "/" :request-method :get})

(hello-world-handler request)
;;=> {:status 200
;;    :headers {"content-type" "text/plain"}
;;    :body "Hello, 12.34.56.78!\n"}

middleware-function.clj

(defn wrap-no-cache [handler]
  (fn [request]
    (let [response (handler request)]
      (update-in response [:headers "cache-control"]
                 (fnil identity "no-cache")))))


(def app (wrap-no-cache hello-world-handler))

(app request)
;;=> {:status 200
;;    :headers {"content-type" "text/plain"
;;              "cache-control" "no-cache"}
;;    :body "Hello, 12.34.56.78!\n"}

typical-ring-request.clj

{:foo bar
 ;;TODO!!!!!
 ;;TODO!!!!!
 }

typical-ring-response.clj

{:status 200
 :headers {"Content-Type" "application/json"
           "Cache-Control" "no-cache"}
 :body "{\"accountId\":27366391,\"balance\":23.21,\"currency\":\"USD\"}"}