Libreoffice 64bitの更新スクリプト。（インストールにも使用可能）

lo_update.bat

@echo off
cls
:: ===============  LibreOffice Update script  ====================
:: これは LibreOffice (x86_64)のインストール or アップデート用スクリプトです。
:: =======================   使い方  ===============================
:: ローカルインストールの場合は、インストールファイルをこのバッチファイルと同じフォルダに置いて
:: ください。  以下のurlからダウンロードできます。
:: http://ja.libreoffice.org/download/libreoffice-fresh/
:: インストールに必要なファイルは「メインインストーラ」と「日本語のLibreOffice組み込み
:: ヘルプ」です。 
:: 
:: オンラインインストールの場合は -g オプションを付けて実行してください。  実行時にインス
:: トールファイルを自動ダウンロードします。
:: ^>lo_update -g 7.2.5
:: 
:: ヘルプオプション -h は、ヘルプを表示します。
:: ^>lo_update -h
:: ================================================================

:: インストールファイル名
:: main file : LibreOffice_7.2.5_Win_x64.msi
:: help file : LibreOffice_7.2.5_Win_x64_helppack_ja.msi
set COM_NAME=LibreOffice_
set MAIN_NAME=_Win_x64.msi
set HELP_NAME=_Win_x64_helppack_ja.msi

:: ダウンロードURL
:: main file 32bit: https://download.documentfoundation.org/libreoffice/stable/7.2.5/win/x86/LibreOffice_7.2.5_Win_x86.msi
:: help file 32bit: https://download.documentfoundation.org/libreoffice/stable/7.2.5/win/x86/LibreOffice_7.2.5_Win_x86_helppack_ja.msi
:: main file 64bit: https://download.documentfoundation.org/libreoffice/stable/7.2.5/win/x86_64/LibreOffice_7.2.5_Win_x64.msi
:: help file 64bit: https://download.documentfoundation.org/libreoffice/stable/7.2.5/win/x86_64/LibreOffice_7.2.5_Win_x64_helppack_ja.msi
set GET_URL1=https://download.documentfoundation.org/libreoffice/stable/
set GET_URL2=/win/x86_64/LibreOffice_

:: ログファイル
set MAIN_LOGNAME=logfileMain.txt
set HELP_LOGNAME=logfileHelppack.txt

:: 引数 無し      : HELPを表示
:: 引数 -h       : HELPを表示
:: 引数 X.X.X    : バージョン X.X.X をインストール
:: 引数 -g X.X.X : バージョン X.X.X をダウンロード後インストール
if "%1"=="" goto HELP
if "%1"=="-h" goto HELP
if "%1"=="-g" goto GET
set F_VERSION=%1

:CHECK
:: インストールファイルの存在確認
echo.
if NOT EXIST %COM_NAME%%F_VERSION%%MAIN_NAME% (
    echo メインインストーラ %COM_NAME%%F_VERSION%%MAIN_NAME% が見つかりません
    goto EXIT
)
if NOT EXIST %COM_NAME%%F_VERSION%%HELP_NAME% (
    echo ヘルプパック %COM_NAME%%F_VERSION%%HELP_NAME% が見つかりません
    goto EXIT
) 
goto INSTALL


:GET
::インストールファイルを取得
if "%2"=="" (
    echo.
    echo ダウンロードするファイルバージョンを指定してください
    goto HELP
)
set F_VERSION=%2
echo.
echo メインインストーラ %COM_NAME%%F_VERSION%%MAIN_NAME% を取得します
echo %GET_URL1%%F_VERSION%%GET_URL2%%F_VERSION%%MAIN_NAME%
echo.
curl.exe -f -L -O %GET_URL1%%F_VERSION%%GET_URL2%%F_VERSION%%MAIN_NAME%
if NOT %ERRORLEVEL%==0 (
    echo.
    echo ファイル %COM_NAME%%F_VERSION%%MAIN_NAME% を取得できませんでした [%ERRORLEVEL%]
    goto EXIT
)
echo.
echo ヘルプパック %COM_NAME%%F_VERSION%%HELP_NAME% を取得します
echo %GET_URL1%%F_VERSION%%GET_URL2%%F_VERSION%%HELP_NAME%
echo.
curl.exe -f -L -O %GET_URL1%%F_VERSION%%GET_URL2%%F_VERSION%%HELP_NAME%
if NOT %ERRORLEVEL%==0 (
    echo.
    echo ファイル %COM_NAME%%F_VERSION%%HELP_NAME% を取得できませんでした [%ERRORLEVEL%]
    goto EXIT
)
goto CHECK


:HELP
:: 使い方を表示
echo ======================================================================
echo ==========       ^<^<  LibreOffice Update script ^>^>          ==========
echo ======================================================================
echo.  
echo 使い方
echo ^> lo_update ^<number^>
echo ^> lo_update ^<option^> ^<number^>
echo.
echo [例：LibreOffice 7.2.5をローカルインストールする場合] 
echo ^>lo_update 7.2.5
echo.
echo [例：LibreOffice 7.2.5のダウンロード後にインストールする場合] 
echo ^>lo_update -g 7.2.5
echo.
echo [このヘルプを表示] 
echo ^>lo_update -h
echo.
echo ======================================================================
goto EXIT


:INSTALL
:: インストール実行とログファイル生成

echo.
echo メインインストーラ %COM_NAME%%F_VERSION%%MAIN_NAME%  を開始します。
msiexec.exe /qb /i %COM_NAME%%F_VERSION%%MAIN_NAME% /Lie %MAIN_LOGNAME%
echo.
echo ヘルプパック %COM_NAME%%F_VERSION%%HELP_NAME% を開始します。
msiexec.exe /qb /i %COM_NAME%%F_VERSION%%HELP_NAME% /Lie %HELP_LOGNAME%


:EXIT
echo.
echo 完了しました。
echo on