gistfile1.pde

// by dave whyte @ bees & bombs >:)
// use gifsicle to assemble frames into gif

int[][] result;
float t;

float ease(float p) {
  return 3*p*p - 2*p*p*p;
}

float ease(float p, float g) {
  if (p < 0.5) 
    return 0.5 * pow(2*p, g);
  else
    return 1 - 0.5 * pow(2*(1 - p), g);
}

float mn = .5*sqrt(3);

void setup() {
  setup_();
  result = new int[width*height][3];
}

void draw() {

  if (!recording) {
    t = mouseX*1.0/width;
    draw_();
  } else {
    for (int i=0; i<width*height; i++)
      for (int a=0; a<3; a++)
        result[i][a] = 0;

    for (int sa=0; sa<samplesPerFrame; sa++) {
      t = map(frameCount-1 + sa*shutterAngle/samplesPerFrame, 0, numFrames, 0, 1);
      draw_();
      loadPixels();
      for (int i=0; i<pixels.length; i++) {
        result[i][0] += pixels[i] >> 16 & 0xff;
        result[i][1] += pixels[i] >> 8 & 0xff;
        result[i][2] += pixels[i] & 0xff;
      }
    }

    loadPixels();
    for (int i=0; i<pixels.length; i++)
      pixels[i] = 0xff << 24 | 
        int(result[i][0]*1.0/samplesPerFrame) << 16 | 
        int(result[i][1]*1.0/samplesPerFrame) << 8 | 
        int(result[i][2]*1.0/samplesPerFrame);
    updatePixels();

    saveFrame("f###.gif");
    if (frameCount==numFrames)
      exit();
  }
}

//////////////////////////////////////////////////////////////////////////////

int samplesPerFrame = 32;
int numFrames = 96;        
float shutterAngle = .6;

boolean recording = false;

void setup_() {
  size(800, 500);
  smooth(8);
  rectMode(CENTER);
  strokeCap(ROUND);
}

float x, y, tt, t1;
float dd;
int N = 5;

void draw_() {
  background(250); 
  pushMatrix();
  translate(width/2, height/2);
  scale(.8*pow(1.72,t));
  fill(0);
  noStroke();
  ellipse(0, 0, 350, 350);
  stroke(250);
  noFill();
  if (t <= .5) {
    tt = constrain(3*t,0,1);
    tt = pow(tt,.5);
    strokeWeight(16*ease(tt,3));
    arc(0, 0, 220, 220, .1, PI-.1);
  } 
  
  else {
    tt = 2*t-1;
    t1 = ease(max(0,1.5*tt-.5),2.5);
    tt = ease(tt,2.5);
    strokeWeight(16+60*t1);
    arc(0, 0, 220+60*t1, 220+60*t1, lerp(.1, -HALF_PI, tt), lerp(PI-.1, PI+HALF_PI, tt));
  }

  popMatrix();
}