PubSubClient sample for ESP8266 Arduino

esp8266_pubsubclient.ino

#include <PubSubClient.h>
#include <ESP8266WiFi.h>

const char* ssid = ".................";
const char* password = "................";

char* topic = "esp8266_arduino_out";
char* server = "iot.eclipse.org";


WiFiClient wifiClient;
PubSubClient client(server, 1883, callback, wifiClient);

void callback(char* topic, byte* payload, unsigned int length) {
  // handle message arrived
}


String macToStr(const uint8_t* mac)
{
  String result;
  for (int i = 0; i < 6; ++i) {
    result += String(mac[i], 16);
    if (i < 5)
      result += ':';
  }
  return result;
}

void setup() {
  Serial.begin(115200);
  delay(10);
  
  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  
  WiFi.begin(ssid, password);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");  
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  // Generate client name based on MAC address and last 8 bits of microsecond counter
  String clientName;
  clientName += "esp8266-";
  uint8_t mac[6];
  WiFi.macAddress(mac);
  clientName += macToStr(mac);
  clientName += "-";
  clientName += String(micros() & 0xff, 16);

  Serial.print("Connecting to ");
  Serial.print(server);
  Serial.print(" as ");
  Serial.println(clientName);
  
  if (client.connect((char*) clientName.c_str())) {
    Serial.println("Connected to MQTT broker");
    Serial.print("Topic is: ");
    Serial.println(topic);
    
    if (client.publish(topic, "hello from ESP8266")) {
      Serial.println("Publish ok");
    }
    else {
      Serial.println("Publish failed");
    }
  }
  else {
    Serial.println("MQTT connect failed");
    Serial.println("Will reset and try again...");
    abort();
  }
}

void loop() {
  static int counter = 0;
  
  String payload = "{\"micros\":";
  payload += micros();
  payload += ",\"counter\":";
  payload += counter;
  payload += "}";
  
  if (client.connected()){
    Serial.print("Sending payload: ");
    Serial.println(payload);
    
    if (client.publish(topic, (char*) payload.c_str())) {
      Serial.println("Publish ok");
    }
    else {
      Serial.println("Publish failed");
    }
  }
  ++counter;
  delay(5000);
}

i have used esp 12e pubsub client. i will sent the message through mqtt using ardunio ide 1,6.5.once upload my code with iot.eclipse.org mqtt server url means data will send . so i change my own mqtt server means message not send it show the error
WiFi connected
IP address:
192.168.100.49
Attempting MQTT connection...failed, rc=-2 try again in 5 seconds

give me any suggestion pls?

Thank you. It works good.
Mosquitto Mqtt broker is on Ubuntu 12.04
I monitor the esp8266 through COM port /dev/ttyUSB0.
I have changed just this:
const char* ssid = "ququ2";
const char* password = "george34";
char* topic = "home/motions/Holl";
char* server = "192.168.1.19";