cutsyntax.scm

;; instead of (cut foo bar <> baz <>)
;; you can do #[foo bar _ baz _]a

(read-hash-extend #\[
  (lambda (char port)
    (let loop ((terms '()) (gensyms '()))
      (let ((c (peek-char port)))
        (cond ((eof-object? c)
               (error 'wtf?))
              ((char-whitespace? c)
               (read-char port)
               (loop terms gensyms))
              ((char=? #\] c)
               (read-char port)
               `(lambda ,(reverse gensyms) ,(reverse terms)))
              ((char=? #\_ c)
               (read-char port)
               (let ((next (peek-char port)))
                 (cond ((or (char-whitespace? next)
                            (char=? #\] next))
                        (let ((g (gensym "_")))
                          (loop (cons g terms) (cons g gensyms))))
                       (else
                        (unread-char #\_ port)
                        (loop (cons (read port) terms) gensyms)))))
              (else
               (loop (cons (read port) terms) gensyms)))))))

If you want to use this in emacs with paredit, I recommend you

(add-to-list 'paredit-space-for-delimiter-predicates
                (lambda (endp delimiter)
                  (not (eql delimiter ?#))))

to your .emacs