Enabling JVMCI and adding Graal compiler to the upgrade-module-path in android unit tests

build.gradle.kts

configurations {
    dependencyScope("graalvmCompiler")
    resolvable("graalvmCompilerClasspath") {
        extendsFrom(configurations["graalvmCompiler"])
    }
}

dependencies {
    add("graalvmCompiler", "org.graalvm.compiler:compiler:24.0.1")
}

val isRunningOnGraalVm: Provider<Boolean> = providers.gradleProperty("GRAALVM")
    .map(String::toBoolean)
    .orElse(
        providers
            .systemProperty("java.home")
            .map { javaHome ->
                Paths.get("$javaHome/lib/graalvm").exists()
            },
    )
    .orElse(false)

android {
    testOptions {
        unitTests.all {
            it.javaLauncher = javaToolchains.launcherFor {
                languageVersion = JavaLanguageVersion.of(22)
            }
            it.jvmArgumentProviders += GraalvmCompilerJvmArgumentsProvider(
                configurations["graalvmCompilerClasspath"],
                isRunningOnGraalVm,
            )
        }
    }
}

class GraalvmCompilerJvmArgumentsProvider(
    @get:InputFiles
    @get:PathSensitive(PathSensitivity.RELATIVE)
    val gralvmClasspath: FileCollection,
    val isGralvm: Provider<Boolean>,
) : CommandLineArgumentProvider {
    override fun asArguments(): Iterable<String> {
        return if (!isGralvm.get()) {
            listOf(
                "-XX:+UnlockExperimentalVMOptions",
                "-XX:+EnableJVMCI",
                "--upgrade-module-path=${gralvmClasspath.asPath}",
            )
        } else {
            emptyList()
        }
    }
}