Some utilities for managing iTunes preferences that are not accessible via AppleScript

itunes_eleven_utilities.applescript

on ensure_playlist_sort_and_list_view()
	-- http://stackoverflow.com/questions/4056812/how-to-change-the-order-of-a-song-within-an-itunes-playlist-by-applescript/13667549#13667549
	tell application "System Events"
		tell process "iTunes"
			-- ensure list view
			try
				outline 1 of scroll area 1 of splitter group 1 of splitter group 1 of window "iTunes"
			on error
				-- then we are not in list view
				click menu button "View" of splitter group 1 of window "iTunes"
				delay 0.25
				keystroke "L"
				delay 0.25
				keystroke return
			end try
			
			-- ensure ascending sorting direction
			set sort_button to button "status" of group 1 of outline 1 of scroll area 1 of splitter group 1 of splitter group 1 of window "iTunes"
			if value of attribute "AXSortDirection" of sort_button is "AXDescendingSortDirection" then
				perform action "AXPress" of sort_button
			end if
		end tell
	end tell
end ensure_playlist_sort_and_list_view

on playlist_repeat_all()
	tell application "System Events" to tell process "iTunes"'s menu bar 1's menu bar item "Controls"'s menu 1's menu item "Repeat"'s menu 1
		perform action "AXPress" of menu item "All"
	end tell
end playlist_repeat_all