Ztest_C_ProductAmount.sql

@AbapCatalog.sqlViewName: 'ZTEST_CPRODAMNT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Available product amount'

define view Ztest_C_ProductAmount
  as select from Ztest_I_ProductAmount

  association [*] to Ztest_C_ProductReplenishment as _Replenishment on _Replenishment.Material = $projection.Material
{
  key Material,
      @EndUserText: {
        label: 'Available Amount',
        quickInfo: 'Amount available across all shops'
      }
      AvailableAmount,

      _Replenishment,
      _Material
}

Ztest_C_ProductReplenishment.sql

@AbapCatalog.sqlViewName: 'ZTEST_CPRODREPL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Replenishment Dates'

define view Ztest_C_ProductReplenishment
  as select from Ztest_I_ProductReplenishment(
                 p_horizon_days: 10,
                 p_current_date: $session.system_date
                 )
{
  key Material,
      @EndUserText.label: 'Shop'
  key ShopID,

      @EndUserText: {
        label: 'Next Replenishment',
        quickInfo: 'Latest replenishment date'
      }
      ReplenishmentDate,

      _Shop,
      _Material
}